net-misc/efax/efax-0.9a-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/efax/efax-0.9a-r3.ebuild,v 1.5 2012/06/08 12:09:45 phajdan.jr Exp $

EAPI=4

inherit eutils

S="${WORKDIR}/${P}-001114"

DESCRIPTION="A simple fax program for single-user systems"
HOMEPAGE="http://gentoo.org"
SRC_URI="http://www.cce.com/efax/download/${P}-001114.tar.gz
	mirror://debian/pool/main/e/efax/efax_0.9a-19.diff.gz"

KEYWORDS="amd64 ppc x86"
IUSE=""
SLOT="0"
LICENSE="GPL-2"

src_prepare () {
	epatch "${WORKDIR}/${PN}_${PV}-19.diff"
	rm -f "${S}"/${P}/debian/patches/series "${S}"/${P}/debian/patches/00list
	EPATCH_FORCE="yes" epatch "${S}"/${P}/debian/patches/*

	epatch "${FILESDIR}/${P}-fax-command.patch" #327737

	# remove strip command as per bug #240932
	sed -i -e '/strip/d' Makefile
}

src_compile() {
	emake CC=$(tc-getCC) CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
}

src_install () {
	dobin efax efix fax
	doman efax.1 efix.1 fax.1
	dodoc README
}