net-libs/telepathy-qt/telepathy-qt-0.9.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-qt/telepathy-qt-0.9.0.ebuild,v 1.1 2012/01/25 08:49:10 johu Exp $

EAPI=4

PYTHON_DEPEND="2:2.5"
inherit python base cmake-utils

DESCRIPTION="Qt4 bindings for the Telepathy D-Bus protocol"
HOMEPAGE="http://telepathy.freedesktop.org/"
SRC_URI="http://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug farsight glib test"

# TODO raise dep if version is available:
# >=net-libs/telepathy-glib-0.17.2
RDEPEND="
	dev-python/dbus-python
	x11-libs/qt-core:4[glib?]
	x11-libs/qt-dbus:4
	farsight? (
		dev-libs/dbus-glib
		dev-libs/libxml2
		media-libs/gstreamer
		net-libs/telepathy-farsight
	)
	glib? (
		dev-libs/glib:2
		>=net-libs/telepathy-glib-0.15.1
	)
	!net-libs/telepathy-qt4
"
DEPEND="${RDEPEND}
	dev-libs/libxslt
	dev-util/pkgconfig
	test? ( x11-libs/qt-test:4 )
"

PATCHES=( "${FILESDIR}/${P}-automagicness.patch" )

DOCS=( AUTHORS ChangeLog HACKING NEWS README )

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	base_src_prepare

	sed -i -e '/^add_subdirectory(examples)$/d' CMakeLists.txt || die
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_enable debug DEBUG_OUTPUT)
		$(cmake-utils_use_with glib)
		$(cmake-utils_use_with farsight)
		$(cmake-utils_use_with test)
	)
	cmake-utils_src_configure
}