blob: 450f17b5990d1234f07d85c49e6c4be90f48808c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libsrtp/libsrtp-1.4.4-r1.ebuild,v 1.7 2009/06/26 10:51:55 aballier Exp $
EAPI="2"
inherit eutils
MY_PN="srtp"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="Open-source implementation of the Secure Real-time Transport Protocol (SRTP)"
HOMEPAGE="http://srtp.sourceforge.net/srtp.html"
SRC_URI="mirror://sourceforge/${MY_PN}/${MY_P}.tgz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 -sparc ~x86 ~x86-fbsd"
IUSE="aesicm console debug doc syslog"
S=${WORKDIR}/${MY_PN}
src_prepare() {
# generate a shared lib
epatch "${FILESDIR}"/${P}-shared.patch
}
src_configure() {
# stdout: default error output for messages in debug
# kernel-linux: breaks the build
# gdoi: disabled by upstream and breaks the build
econf \
--enable-stdout \
--disable-kernel-linux \
--disable-gdoi \
$(use_enable aesicm generic-aesicm) \
$(use_enable console) \
$(use_enable debug) \
$(use_enable syslog)
}
src_compile() {
# target all is building test
emake ${PN}.a ${PN}.so || die "emake failed"
}
src_test() {
# getopt returns an int, not a char
sed -i -e "s/char q/int q/" \
test/rdbx_driver.c test/srtp_driver.c test/dtls_srtp_driver.c \
|| die "fixing getopt errors failed"
# test/rtpw_test.sh is assuming . is in $PATH
sed -i -e "s:\$RTPW :./\$RTPW :" test/rtpw_test.sh \
|| die "patching test/rtpw_test.sh failed"
# test/rtpw.c is using /usr/share/dict/words assuming it exists
# using test/rtpw.c guaratees the file exists in any case
sed -i -e "s:/usr/share/dict/words:rtpw.c:" test/rtpw.c \
|| die "patching test/rtpw.c failed"
emake test || die "building test failed"
emake -j1 runtest || die "tests failed"
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
dodoc CHANGES README TODO || die "dodoc failed"
if use doc; then
# libsrtp.pdf can also be generated with doxygen
# but it would be a waste of time as an up-to-date version is built
dodoc doc/*.txt doc/${PN}.pdf || die "dodoc failed"
fi
}
|
GitWeb
