blob: aa3d87dfaf0b496b60610a39d99f289a094d76bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.2.5.ebuild,v 1.1 2012/01/14 10:45:04 vapier Exp $
EAPI="4"
inherit eutils flag-o-matic multilib autotools
DESCRIPTION="NFS client and server daemons"
HOMEPAGE="http://linux-nfs.org/"
SRC_URI="mirror://sourceforge/nfs/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="caps ipv6 kerberos nfsidmap +nfsv4 nfsv41 selinux tcpd elibc_glibc"
RESTRICT="test" #315573
# kth-krb doesn't provide the right include
# files, and nfs-utils doesn't build against heimdal either,
# so don't depend on virtual/krb.
# (04 Feb 2005 agriffis)
DEPEND_COMMON="tcpd? ( sys-apps/tcp-wrappers )
caps? ( sys-libs/libcap )
sys-libs/e2fsprogs-libs
net-nds/rpcbind
net-libs/libtirpc
nfsv4? (
>=dev-libs/libevent-1.0b
>=net-libs/libnfsidmap-0.21-r1
kerberos? (
net-libs/librpcsecgss
net-libs/libgssglue
net-libs/libtirpc[kerberos]
app-crypt/mit-krb5
)
nfsidmap? (
>=net-libs/libnfsidmap-0.24
sys-apps/keyutils
)
)
selinux? (
sec-policy/selinux-rpc
sec-policy/selinux-rpcbind
)"
RDEPEND="${DEPEND_COMMON} !net-nds/portmap"
# util-linux dep is to prevent man-page collision
DEPEND="${DEPEND_COMMON}
dev-util/pkgconfig
!<sys-apps/util-linux-2.12r-r7"
src_prepare() {
epatch "${FILESDIR}"/${PN}-1.1.4-mtab-sym.patch
epatch "${FILESDIR}"/${PN}-1.2.4-cross-build.patch
epatch "${FILESDIR}"/${PN}-1.2.4-no-nfsctl.patch
eautoreconf
}
src_configure() {
export ac_cv_header_keyutils_h=$(usex nfsidmap)
econf \
--with-statedir=/var/lib/nfs \
--enable-tirpc \
$(use_with tcpd tcp-wrappers) \
$(use_enable nfsv4) \
$(use_enable nfsv41) \
$(use_enable ipv6) \
$(use_enable caps) \
$(use nfsv4 && use_enable kerberos gss || echo "--disable-gss")
}
src_install() {
emake DESTDIR="${ED}" install
dodoc -r linux-nfs ChangeLog README
# Don't overwrite existing xtab/etab, install the original
# versions somewhere safe... more info in pkg_postinst
keepdir /var/lib/nfs/{,sm,sm.bak}
mv "${ED}"/var/lib "${ED}"/usr/$(get_libdir) || die
# Install some client-side binaries in /sbin
dodir /sbin
mv "${ED}"/usr/sbin/rpc.statd "${ED}"/sbin/ || die
insinto /etc
doins "${FILESDIR}"/exports
local f list="" opt_need=""
if use nfsv4 ; then
opt_need="rpc.idmapd"
list="${list} rpc.idmapd rpc.pipefs"
use kerberos && list="${list} rpc.gssd rpc.svcgssd"
fi
for f in nfs nfsmount rpc.statd ${list} ; do
newinitd "${FILESDIR}"/${f}.initd ${f}
done
newconfd "${FILESDIR}"/nfs.confd nfs
sed -i \
-e "/^NFS_NEEDED_SERVICES=/s:=.*:=\"${opt_need}\":" \
"${ED}"/etc/conf.d/nfs || die #234132
# uClibc doesn't provide rpcgen like glibc, so lets steal it from nfs-utils
if ! use elibc_glibc ; then
dobin tools/rpcgen/rpcgen
newdoc tools/rpcgen/README README.rpcgen
fi
}
pkg_postinst() {
# Install default xtab and friends if there's none existing. In
# src_install we put them in /usr/lib/nfs for safe-keeping, but
# the daemons actually use the files in /var/lib/nfs. #30486
local f
mkdir -p "${ROOT}"/var/lib/nfs #368505
for f in "${ROOT}"/usr/$(get_libdir)/nfs/*; do
[[ -e ${ROOT}/var/lib/nfs/${f##*/} ]] && continue
einfo "Copying default ${f##*/} from /usr/$(get_libdir)/nfs to /var/lib/nfs"
cp -pPR "${f}" "${ROOT}"/var/lib/nfs/
done
}
|
GitWeb