net-dialup/minicom/minicom-2.1-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/minicom/minicom-2.1-r2.ebuild,v 1.2 2005/12/25 15:09:39 flameeyes Exp $

inherit eutils flag-o-matic

DESCRIPTION="Serial Communication Program"
HOMEPAGE="http://alioth.debian.org/projects/minicom"
SRC_URI="http://alioth.debian.org/download.php/123/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE=""

DEPEND=">=sys-libs/ncurses-5.2-r3"
RDEPEND="${DEPEND}
	net-dialup/lrzsz"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# solar@gentoo.org (Mar 24 2004)
	# propolice/ssp caught minicom going out of bounds here.
	epatch "${FILESDIR}"/${P}-memcpy-bounds.diff
	epatch "${FILESDIR}"/${P}-gcc4.patch
	epatch "${FILESDIR}"/${P}-gentoo-runscript.patch
}

src_compile() {
	# avoid lazy binding (minicom is sgided)
	append-ldflags $(bindnow-flags)

	econf --sysconfdir=/etc/${PN} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	einstall || die "einstall failed"

	#minicom must be uucp sgided is needed for being able to lock serial ports
	#when run as simple user
	fowners root:uucp /usr/bin/minicom
	fperms g+s /usr/bin/minicom

	dodoc doc/minicom.FAQ
	insinto /etc/minicom
	doins "${FILESDIR}"/minirc.dfl

	dodoc AUTHORS ChangeLog NEWS README
}

pkg_preinst() {
	[[ -s /etc/minicom/minirc.dfl ]] \
		&& rm -f "${IMAGE}"/etc/minicom/minirc.dfl
}