media-video/ogle/ogle-0.9.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/ogle/ogle-0.9.1.ebuild,v 1.12 2005/09/10 15:38:09 flameeyes Exp $

inherit eutils libtool

IUSE="oss mmx alsa xv"

DESCRIPTION="Full featured DVD player that supports DVD menus."
HOMEPAGE="http://www.dtek.chalmers.se/groups/dvd/"
SRC_URI="http://www.dtek.chalmers.se/groups/dvd/dist/${P}.tar.gz"

SLOT="0"
KEYWORDS="x86 ppc ~sparc ~alpha ~hppa ~amd64 ~ia64"
LICENSE="GPL-2"

DEPEND=">=media-libs/libdvdcss-1.2.2
	media-libs/jpeg
	>=media-libs/libdvdread-0.9.4
	media-sound/madplay
	virtual/x11
	>=dev-libs/libxml2-2.4.19
	>=media-libs/a52dec-0.7.3
	alsa? ( media-libs/alsa-lib )"

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/ogle-configure-alsa-fix.patch || die "failed applying alsa-fix"
	epatch ${FILESDIR}/ogle-gcc34-fix.patch
}

src_compile() {
	# STOP!  If you make any changes, make sure to unmerge all copies
	# of ogle and ogle-gui from your system and merge ogle-gui using your
	# new version of ogle... Changes in this package can break ogle-gui
	# very very easily -- blocke

	local myconf="`use_enable mmx` `use_enable oss` `use_enable alsa`"

	use xv && myconf="${myconf} --enable-xv" || myconf="${myconf} --disable-xv"

	if [ "${ARCH}" = "ppc" ] ; then
		# if this user doesn't want altivec, don't compile it in
		# fixes #14939
		if [ `echo ${CFLAGS} | grep -e "-maltivec" | wc -l` = "0" ]
		then
			einfo "Disabling alitvec support"
			myconf="${myconf} --disable-altivec"
		else
			einfo "Enabling altivec support"
			myconf="${myconf} --enable-altivec"
		fi
	fi

	elibtoolize

	# configure needs access to the updated CFLAGS
	CFLAGS="${CFLAGS} -I/usr/include/libxml2/libxml -I/usr/include/libxml2"

	econf ${myconf} || die
	emake CFLAGS="${CFLAGS}" || die
}

src_install() {
	einstall || die
	dodoc AUTHORS ChangeLog HISTORY NEWS README TODO
	dodoc doc/liba52.txt
}