media-sound/prokyon3/prokyon3-0.9.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/prokyon3/prokyon3-0.9.4.ebuild,v 1.3 2006/03/08 20:29:56 flameeyes Exp $

inherit qt3 eutils

DESCRIPTION="Multithreaded music manager and tag editor based on Qt and MySQL."
HOMEPAGE="http://prokyon3.sourceforge.net"
SRC_URI="mirror://sourceforge/prokyon3/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="flac mp3 musicbrainz vorbis"

DEPEND="=x11-libs/qt-3*
	media-libs/taglib
	musicbrainz? ( media-libs/musicbrainz
		mp3? ( media-libs/libmad )
		vorbis? ( media-libs/libvorbis )
		flac? ( media-libs/flac ) )"

pkg_setup() {
	if ! built_with_use x11-libs/qt mysql; then
		eerror "You have installed Qt without MySQL support."
		eerror "Please reemerge x11-libs/qt with "mysql" in USE."
		die "MySQL support for Qt not found."
	fi
}

src_compile() {
	# Support for musicextras (not in portage)
	# requires dev-libs/xmlwrapp.

	local myconf="--with-taglib
			--without-id3
			--without-mysql-embedded
			--without-musicextras"

	if use musicbrainz; then
		myconf="${myconf}
			--with-musicbrainz
			$(use_with mp3 mad)
			$(use_with vorbis ogg)
			$(use_with flac)"
	else
		myconf="${myconf}
			--without-musicbrainz"
	fi

	econf ${myconf}	|| die "configure failed"
	emake || die "make failed"
}

src_install () {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog NEWS README
}

pkg_postinst() {
	echo
	einfo "Prokyon3 supports the following external programs"
	einfo "to play audio tracks:"
	einfo " - media-sound/amarok"
	einfo " - media-sound/beep-media-player"
	einfo " - media-video/kaffeine"
	einfo " - media-video/mplayer"
	einfo " - kde-base/noatun or kde-base/kdemultimedia"
	einfo " - media-video/totem"
	einfo " - media-sound/xmms"
	einfo
	einfo "Prokyon3 also supports the following external"
	einfo "applications, if installed:"
	einfo " - app-cdr/k3b:          CD burning"
	einfo " - media-sound/mixxx:    DJ mixing"
	echo
}