media-libs/quesoglc/quesoglc-0.7.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/quesoglc/quesoglc-0.7.2.ebuild,v 1.2 2009/11/14 20:40:58 maekke Exp $

EAPI=2
DESCRIPTION="A free implementation of the OpenGL Character Renderer (GLC)"
HOMEPAGE="http://quesoglc.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}-free.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 ~ppc ~sparc x86"
IUSE="doc examples"

RDEPEND="virtual/opengl
	virtual/glu
	media-libs/fontconfig
	media-libs/freetype:2
	dev-libs/fribidi"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

src_prepare() {
	rm -rf src/fribidi
}

src_configure() {
	# Uses its own copy of media-libs/glew with GLEW_MX
	econf \
		--disable-dependency-tracking \
		--disable-executables \
		--with-fribidi \
		--without-glew
}

src_compile() {
	emake || die "emake failed"
	if use doc ; then
		cd docs
		doxygen -u Doxyfile && doxygen || die "doxygen failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog README THANKS
	if use doc ; then
		dohtml docs/html/* || die "dohtml failed"
	fi
	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.c || die "doins failed"
	fi
}