media-libs/allegro/allegro-4.0.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/allegro-4.0.2.ebuild,v 1.8 2003/04/25 13:08:16 vapier Exp $

inherit flag-o-matic

DESCRIPTION="cross-platform multimedia library"
SRC_URI="mirror://sourceforge/alleg/${P}.tar.gz"
HOMEPAGE="http://alleg.sourceforge.net/"

LICENSE="Allegro"
SLOT="0"
KEYWORDS="x86 sparc"
IUSE="mmx esd static tetex X fbcon oss svga alsa"

RDEPEND="X? ( virtual/x11 )
	alsa? ( media-libs/alsa-lib )
	esd? ( media-sound/esound )
	svga? ( media-libs/svgalib )"
DEPEND="${RDEPEND}
	tetex? ( app-text/tetex )"

src_compile() {
	# Always enable Linux console support and accompanying drivers
	confopts="${confopts} --enable-linux --enable-vga"
	
	# if USE static defined, use static library as default to link with
	use static \
		&& confopts="${confopts} --enable-staticprog --enable-static"
	
	# Pentium optimizations
	if [ ${CHOST} = "i586-pc-linux-gnu" -o ${CHOST} = "i686-pc-linux-gnu" ]
	then 
		confopts="${confopts} --enable-pentiumopts"
	fi
	
	# Use MMX instructions
	use mmx \
		&& confopts="${confopts} --enable-mmx" \
		|| confopts="${confopts} --enable-mmx=no"
	
	# Have OSS support
	use oss \
		&& confopts="${confopts} --enable-ossdigi --enable-ossmidi" \
		|| confopts="${confopts} --disable-ossdigi --disable-ossmidi"
	
	# Have ALSA support
	use alsa \
		&& confopts="${confopts} --enable-alsadigi --enable-alsamidi" \
		|| confopts="${confopts} --disable-alsadigi --disable-alsamidi"
	
	# Have ESD support
	use esd \
		&& confopts="${confopts} --enable-esddigi" \
		|| confopts="${confopts} --disable-esddigi"
	
	# Have X11 support
	use X \
		&& confopts="${confopts} \
			--with-x \
			--enable-xwin-shm \
			--enable-xwin-vidmode \
			--enable-xwin-dga \
			--enable-xwin-dga2" \
		|| confopts="${confopts} \
			--without-x \
			--disable-xwin-shm \
			--disable-xwin-vidmode \
			--disable-xwin-dga \
			--disable-xwin-dga2"
	
	# Have SVGALib support
	use svga \
		&& confopts="${confopts} --enable-svgalib" \
		|| confopts="${confopts} --disable-svgalib"
	
	# Have fbcon support
	use fbcon \
		&& confopts="${confopts} --enable-fbcon" \
		|| confopts="${confopts} --disable-fbcon"

	# --------------

	econf ${confopts} || die
	
	# emake doesn't work
	filter-flags -fPIC
	make CFLAGS="${CFLAGS/-fPIC/}" || die
	
	if use tetex;
	then
		addwrite "/var/lib/texmf"
		addwrite "/usr/share/texmf"
		addwrite "/var/cache/fonts"
		make docs-dvi docs-ps || die
	fi
	
}

src_install() {
	make \
		prefix=${D}/usr \
		infodir=${D}/usr/share/info \
		mandir=${D}/usr/share/man \
		install install-gzipped-man install-gzipped-info || die
	
	# Different format versions of the Allegro documentation

	dodoc AUTHORS CHANGES THANKS readme.txt todo.txt

	if use tetex;
	then 
		dodoc docs/allegro.dvi docs/allegro.ps
	fi

	dohtml docs/html/*

	docinto txt
	dodoc docs/txt/*.txt

	docinto rtf
	dodoc docs/rtf/*.rtf
	
	docinto build
	dodoc docs/build/*.txt
}