media-gfx/iv/iv-2.1.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/iv/iv-2.1.4.ebuild,v 1.5 2008/01/19 13:39:12 nixnut Exp $

inherit eutils

DESCRIPTION="A basic image viewer for GTK+-1.2"
HOMEPAGE="http://wolfpack.twu.net/IV/"
SRC_URI="ftp://wolfpack.twu.net/users/wolfpack/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="ppc x86"
IUSE="gif imlib jpeg png xpm"

DEPEND="=x11-libs/gtk+-1.2*
	gif? ( >=media-libs/giflib-4.1.0-r3 )
	imlib? ( >=media-libs/imlib-1.9.13 )
	jpeg? ( >=media-libs/jpeg-6b )
	png? ( >=media-libs/libpng-1.2 )
	xpm? ( x11-libs/libXpm )"

src_unpack() {
	unpack ${A}

	# don't prestrip files
	sed -i -e 's:-m 0755 -s:-m 0755:g' "${S}"/iv/Makefile.install.UNIX || die
}

src_compile() {
	./configure Linux --prefix=/usr \
		--disable="arch-i486" \
		--disable="arch-i586" \
		--disable="arch-i686" \
		--disable="arch-pentiumpro" \
		$(use_enable gif libgif) \
		$(use_enable imlib Imlib) \
		$(use_enable imlib Imlib-transpixel-fix) \
		$(use_enable jpeg libjpeg) \
		$(use_enable png libpng) \
		$(use_enable xpm libxpm) \
		--CFLAGS="${CFLAGS}" \
		|| die "configure failed"
	emake || die "make failed"
}

src_install() {
	make install \
		PREFIX="${D}"/usr \
		MAN_DIR="${D}"/usr/share/man/man1 \
		|| die "make install failed"

	dodoc README

	# eog.desktop uses name Image Viewer, so differentiate
	make_desktop_entry iv "IV Image Viewer" /usr/share/icons/iv.xpm "Graphics;Viewer"
}