kde-base/marble/marble-4.2.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/marble-4.2.2.ebuild,v 1.2 2009/04/13 00:08:29 scarabeus Exp $

EAPI="2"

KMNAME="kdeedu"
CPPUNIT_REQUIRED="optional"
KDE_REQUIRED="optional"
inherit kde4-meta

DESCRIPTION="Generic geographical map widget"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~x86"
IUSE="debug designer-plugin doc +kde gps plasma python"

DEPEND="
	gps? ( sci-geosciences/gpsd )
	python? (
		>=dev-python/PyQt4-4.4.4-r1
		kde? ( >=kde-base/pykde4-${PV}:${SLOT} )
	)
"
RDEPEND="${DEPEND}
	!kdeprefix? ( !sci-geosciences/marble )
"

pkg_setup() {
	if use plasma && ! use kde; then
		echo
		eerror "KDE integration is required to build marble world clock applet."
		eerror
		eerror "Either enable 'kde' USE flag or disable 'plasma'."
		eerror "You can do this by setting these flags in /etc/portage/package.use, like:"
		eerror "    =${CATEGORY}/${PN}-${PV} kde plasma"
		echo
		die "Conflicting USE flags found"
	fi

	kde4-meta_pkg_setup
}

src_configure() {
	mycmakeargs="${mycmakeargs}
		$(cmake-utils_use_with designer-plugin DESIGNER_PLUGIN)
		$(cmake-utils_use_with plasma Plasma)
		$(cmake-utils_use_with python PyQt4)
		$(cmake-utils_use_with python PythonLibrary)
		$(cmake-utils_use_with python SIP)"

	sed -i \
		-e 's:add_subdirectory(cmake):#dontwantit:g' \
		CMakeLists.txt || die "sed to disable file collisions failed"

	find "${S}/marble/src/bindings/python/sip" -name "*.sip" | xargs -- sed -i 's/#include <marble\//#include </'

	if use gps; then
		mycmakeargs="${mycmakeargs} -DHAVE_LIBGPS=1"
	else
		sed -i -e 's:FIND_LIBRARY(libgps_LIBRARIES gps):# LIBGPS DISABLED &:' \
			marble/Findlibgps.cmake || die "sed to disable gpsd failed."
	fi

	if use kde; then
		mycmakeargs="${mycmakeargs} $(cmake-utils_use_with python PyKDE4)"
	else
		mycmakeargs="${mycmakeargs} -DQTONLY=ON -DWITH_PyKDE4=OFF"
	fi

	kde4-meta_src_configure
}