kde-apps/lokalize/lokalize-4.14.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-apps/lokalize/lokalize-4.14.3.ebuild,v 1.1 2015/06/04 18:44:46 kensington Exp $

EAPI=5

KDE_HANDBOOK="optional"
PYTHON_COMPAT=( python2_7 )
inherit python-single-r1 kde4-base

DESCRIPTION="KDE4 translation tool"
HOMEPAGE="http://www.kde.org/applications/development/lokalize
http://l10n.kde.org/tools"
KEYWORDS="amd64 ~arm ppc ppc64 x86 ~amd64-linux ~x86-linux"
IUSE="debug nepomuk"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

DEPEND="
	${PYTHON_DEPS}
	>=app-text/hunspell-1.2.8
	>=dev-qt/qtsql-4.5.0:4[sqlite]
	nepomuk? ( >=dev-libs/soprano-2.9.0 )
"
RDEPEND="${DEPEND}
	$(add_kdeapps_dep kdesdk-strigi-analyzer)
	$(add_kdebase_dep krosspython "${PYTHON_USEDEP}")
	$(add_kdebase_dep pykde4 "${PYTHON_USEDEP}")
"

pkg_setup() {
	python-single-r1_pkg_setup
	kde4-base_pkg_setup
}

src_install() {
	kde4-base_src_install
	python_fix_shebang "${ED}/usr/share/apps/${PN}"
}

pkg_postinst() {
	kde4-base_pkg_postinst

	if ! has_version dev-vcs/subversion ; then
		elog "To be able to autofetch KDE translations in new project wizard, install dev-vcs/subversion."
	fi
}