games-strategy/widelands/widelands-0.0.9.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/widelands/widelands-0.0.9.5.ebuild,v 1.6 2006/01/09 12:13:24 genstef Exp $

inherit eutils games

DESCRIPTION="A game similar to Settlers 2"
HOMEPAGE="http://widelands.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-b${PV:4:1}half-source.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug"

DEPEND="media-libs/libpng
	media-libs/libsdl
	media-libs/sdl-image
	media-libs/sdl-mixer
	media-libs/sdl-net
	media-libs/sdl-ttf
	sys-libs/zlib"
RDEPEND=${DEPEND}

S=${WORKDIR}/${PN}-b9half

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/widelands-0.0.9-amd64.patch"
	sed -i -e "s:__ppc__:__PPC__:g" "${S}/src/machdep.h" || die "sed failed"
}

src_compile() {
	use debug || export BUILD="release"
	use elibc_glibc && export IMPLICIT_LIBINTL=1
	emake || die "emake failed"
	unset BUILD IMPLICIT_LIBINTL
}

src_install() {
	local dir=${GAMES_DATADIR}/${PN}

	insinto "${dir}"
	doins -r fonts maps pics tribes worlds campaigns \
		|| die "doins failed"
	exeinto "${dir}"
	doexe ${PN} || die "copying widelands"
	games_make_wrapper widelands ./widelands "${dir}"
	dodoc AUTHORS ChangeLog README.developers

	newicon pics/wl-ico-48.png widelands.png
	make_desktop_entry widelands Widelands widelands.png
	prepgamesdirs
}