games-sports/ultimatestunts/ultimatestunts-0.7.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-sports/ultimatestunts/ultimatestunts-0.7.5.ebuild,v 1.1 2008/06/23 17:30:44 mr_bones_ Exp $

inherit autotools eutils versionator games

MY_P=${PN}-srcdata-$(replace_all_version_separators)1
DESCRIPTION="Remake of the famous Stunts game"
HOMEPAGE="http://www.ultimatestunts.nl/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls"

RDEPEND="media-libs/libsdl
	media-libs/sdl-image
	media-libs/openal
	media-libs/freealut
	virtual/opengl
	virtual/glu
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	dev-util/cvs
	sys-devel/gettext"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	games_pkg_setup
	if ! built_with_use media-libs/libsdl opengl ; then
		die "Please emerge libsdl with USE=opengl"
	fi
	if ! built_with_use media-libs/openal vorbis ; then
		die "Please emerge openal with USE=vorbis"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	ecvs_clean
	epatch "${FILESDIR}"/${P}-paths.patch
	autopoint -f || die "autopoint failed"
	sed -i \
		-e 's:$(datadir)/locale:@top_srcdir@/data/lang:' \
		po/Makefile.in.in \
		|| die "sed failed"
	AT_M4DIR=m4 eautoreconf
}

src_compile() {
	egamesconf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		|| die
	emake -C trackedit libtrackedit.a || die "emake failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	newicon data/cars/diablo/steer.png ${PN}.png
	make_desktop_entry ustunts "Ultimate Stunts"
	dodoc AUTHORS README
	prepgamesdirs
}