games-mud/powwow/powwow-1.2.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-mud/powwow/powwow-1.2.5.ebuild,v 1.4 2005/05/17 18:37:29 wolf31o2 Exp $

inherit toolchain-funcs eutils games

DESCRIPTION="PowWow Console MUD Client"
HOMEPAGE="http://linuz.sns.it/~max/powwow/"
SRC_URI="http://linuz.sns.it/~max/powwow/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86 ~ppc ~amd64"
IUSE=""

DEPEND=">=sys-libs/ncurses-5.2"

POWWOWDIR="${GAMES_DATADIR}/${PN}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PV}-copyfile.patch"
}

src_compile() {
	emake \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS} -DUSE_REGEXP -DPOWWOW_DIR=\"\\\"${POWWOWDIR}\\\"\"" \
		LDFLAGS="-lncurses" \
		powwow movie \
		|| die "emake failed"
}

src_install () {
	dogamesbin powwow || die "dogamesbin failed"
	newgamesbin movie movie_play
	dosym movie_play "${GAMES_BINDIR}/movie2ascii"
	insinto "${POWWOWDIR}"
	doins powwow.help COPYING || die "doins failed"
	dodoc README.* powwow.doc powwow-1.2.5.lsm Compile.how \
		Hacking Config.demo Changelog
	prepgamesdirs
}