games-emulation/fceultra/fceultra-0.97.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/fceultra/fceultra-0.97.4.ebuild,v 1.1 2003/11/10 05:05:25 vapier Exp $

inherit games gcc eutils

DESCRIPTION="A portable NES/Famicom emulator"
HOMEPAGE="http://fceultra.sourceforge.net/"
SRC_URI="http://xodnizel.net/fceultra/downloads/fceu-${PV}.src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~x86"
IUSE="sdl svga"

# Because of code generation bugs, FCEUltra now depends on a version
# of gcc greater than or equal to GCC 3.2.2.
DEPEND="|| (
		svga? ( media-libs/svgalib )
		sdl? ( media-libs/libsdl )
		media-libs/libsdl
	)
	>=sys-devel/gcc-3.2.2
	sys-libs/zlib"

S=${WORKDIR}/fceu

src_unpack() {
	unpack ${A}

	cd ${S}
	epatch ${FILESDIR}/${PV}-stereo.patch
	epatch ${FILESDIR}/${PV}-joystick.patch
	sed -i \
		-e 's:-mcpu=i686 -O2::' \
		-e 's:-fomit-frame-pointer::' \
		Makefile.linuxvga Makefile.unixsdl Makefile.unixsdl.gtk
	sed -i \
		-e "s:\${TFLAGS}:\${TFLAGS} ${CFLAGS}:" \
		Makefile.base
}

src_compile() {
	if [ `use sdl` ] || [ -z "`use sdl``use svga`" ] ; then
		make -f Makefile.unixsdl || die "sdl make failed"
		mv fceu fceu-sdl
		make -f Makefile.unixsdl clean
	fi
	if [ `use svga` ] ; then
		make -f Makefile.linuxvga || die "svga make failed"
		mv fceu fceu-svga
	fi
}

src_install() {
	use sdl && dogamesbin fceu-sdl
	use svga && dogamesbin fceu-svga
	use sdl || use svga || dogamesbin fceu-sdl
	dodoc Documentation/{*,rel/readme-linux.txt}
	prepgamesdirs
}