games-action/towbowl-tactics/towbowl-tactics-0.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-action/towbowl-tactics/towbowl-tactics-0.5.ebuild,v 1.11 2011/01/10 17:43:55 mr_bones_ Exp $

EAPI=2
inherit eutils games

DESCRIPTION="Tow Bowl Tactics is a game based on Games Workshop's Blood Bowl"
HOMEPAGE="http://www.towbowltactics.com/index_en.html"
SRC_URI="http://www.towbowltactics.com/download/tbt.${PV}.src.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc x86"
IUSE=""

RDEPEND="dev-libs/libxml2
	media-libs/smpeg
	media-libs/libsdl[audio,video]
	media-libs/sdl-net
	media-libs/sdl-image[jpeg,png]
	media-libs/sdl-mixer"
DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}/tbt/src

src_prepare() {
	cd  ..
	edos2unix $(find src -type f) config.xml
	epatch "${FILESDIR}"/${P}-gentoo.patch
	sed -i \
	    -e "/^TBTHOME/ s:/.*:${GAMES_DATADIR}/tbt:" \
		src/Makefile || die
	sed -i \
		-e "/tbt.ico/ s:\"\./:TBTHOME \"/:" \
		src/Main.cpp || die
	sed -i \
		-e "s:TBTHOME \"/config.xml:\"${GAMES_SYSCONFDIR}/tbt/config.xml:g" \
		src/global.h || die
}

src_install() {
	dogamesbin tbt || die
	dodir "${GAMES_DATADIR}/tbt"
	cp -r ../data ../tbt.ico "${D}${GAMES_DATADIR}/tbt" || die
	insinto "${GAMES_SYSCONFDIR}/tbt"
	doins ../config.xml || die
	newicon ../data/images/panel/turn.png ${PN}.png || die
	make_desktop_entry tbt "Tow Bowl Tactics" || die
	prepgamesdirs
}