dev-vcs/git-flow/git-flow-1.8.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-flow/git-flow-1.8.0.ebuild,v 1.1 2015/01/26 21:06:09 johu Exp $

EAPI=5

MY_PN="${PN/-/}"
COMP_PN="${PN}-completion"
COMP_PV="0.5.1"
COMP_P="${COMP_PN}-${COMP_PV}"
inherit eutils bash-completion-r1

DESCRIPTION="Git extensions to provide high-level repository operations for Vincent Driessen's branching model"
HOMEPAGE="https://github.com/petervanderdoes/gitflow"
SRC_URI="https://github.com/petervanderdoes/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
https://github.com/petervanderdoes/${COMP_PN}/archive/${COMP_PV}.tar.gz -> ${COMP_P}.tar.gz"

LICENSE="BSD MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=""
RDEPEND="${DEPEND}
	dev-util/shflags
	dev-vcs/git
"

DOCS=( AUTHORS Changes.mdown README.mdown )

PATCHES=( "${FILESDIR}/${P}-unbundle-shflags.patch" )

S="${WORKDIR}/${MY_PN}-${PV}"

src_prepare() {
	[[ ${PATCHES[@]} ]] && epatch "${PATCHES[@]}"
	debug-print "$FUNCNAME: applying user patches"
	epatch_user
}

src_compile() {
	true
}

src_install() {
	emake prefix="${D}/usr" install

	[[ ${DOCS[@]} ]] && dodoc "${DOCS[@]}"

	newbashcomp "${WORKDIR}/${COMP_P}/${COMP_PN}.bash" ${PN}
}