blob: d97f985211873824366cb1d6fb3923ae78b695dc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-tcltk/blt/blt-2.4z-r7.ebuild,v 1.1 2010/03/21 20:05:21 jlec Exp $
EAPI="3"
inherit eutils flag-o-matic toolchain-funcs
MY_V_SUFFIX="-8.5.2"
HOMEPAGE="http://blt.sourceforge.net/
http://jos.decoster.googlepages.com/bltfortk8.5.2"
SRC_URI="http://jos.decoster.googlepages.com/${PN}${PV}${MY_V_SUFFIX}.tar.gz"
DESCRIPTION="BLT is an extension to the Tk toolkit adding new widgets, geometry managers, and misc commands."
IUSE="jpeg X"
SLOT="0"
LICENSE="BSD"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
DEPEND="
>=dev-lang/tk-8.0
jpeg? ( media-libs/jpeg:0 )
X? ( x11-libs/libX11 )"
RDEPEND="${DEPEND}"
S="${WORKDIR}/${PN}${PV}${MY_V_SUFFIX}"
src_prepare() {
epatch "${FILESDIR}/blt-2.4z-r4-fix-makefile.patch"
epatch "${FILESDIR}/blt-2.4z-r4-fix-makefile2.patch"
# From blt-2.4z-6mdk.src.rpm
epatch "${FILESDIR}"/blt2.4z-64bit.patch
#epatch "${FILESDIR}"/blt-2.4z-tcl8.5-fix.patch
epatch "${FILESDIR}"/blt-2.4z-tcl8.5-fixpkgruntime.patch
epatch "${FILESDIR}"/${P}-ldflags.patch
# Set the correct libdir
sed -i -e "s:\(^libdir=\${exec_prefix}/\)lib:\1$(get_libdir):" \
configure* || die "sed configure* failed"
sed -i -e "/^scriptdir =/s:lib:$(get_libdir):" \
Makefile.in demos/Makefile.in || die "sed Makefile.in failed"
}
src_configure() {
# bug 167934
append-flags -fPIC
econf \
--x-includes="${EPREFIX}"/usr/include \
--x-libraries="${EPREFIX}"/usr/$(get_libdir) \
--with-blt="${EPREFIX}"/usr/$(get_libdir) \
--with-tcl="${EPREFIX}"/usr/$(get_libdir) \
--with-tk="${EPREFIX}"/usr/$(get_libdir) \
--with-tclincls="${EPREFIX}"/usr/include \
--with-tkincls="${EPREFIX}"/usr/include \
--with-tcllibs="${EPREFIX}"/usr/$(get_libdir) \
--with-tklibs="${EPREFIX}"/usr/$(get_libdir) \
--with-cc="$(tc-getCC)" \
--with-cflags="${CFLAGS}" \
$(use_enable jpeg) \
$(use_with X x) \
|| die "./configure failed"
}
src_compile() {
# parallel borks
emake -j1 LDFLAGS="${LDFLAGS}" || die "emake failed"
}
src_install() {
sed \
-e "s:../src/bltwish:${EPREFIX}/usr/bin/bltwish:g" \
-e "s:../bltwish:${EPREFIX}/usr/bin/bltwish:g" \
-e "s:/usr/local/bin/bltwish:${EPREFIX}/usr/bin/bltwish:g" \
-e "s:/usr/local/bin/tclsh:${EPREFIX}/usr/bin/tclsh:g" \
-i demos/{,scripts/}*.tcl || die
dodir /usr/bin \
/usr/$(get_libdir)/blt2.4/demos/bitmaps \
/usr/share/man/mann \
/usr/include \
|| die "dodir failed"
emake -j1 INSTALL_ROOT="${D}" install || die "make install failed"
dodoc NEWS PROBLEMS README
dohtml html/*.html
for f in `ls "${ED}"/usr/share/man/mann` ; do
mv "${ED}"/usr/share/man/mann/${f} "${ED}"/usr/share/man/mann/${f/.n/.nblt}
done
# bug 259338 - dev-tcltk/blt-2.4z-r4 provides empty pkgIndex.tcl
cp "${FILESDIR}"/pkgIndex.tcl "${ED}"/usr/$(get_libdir)/blt2.4/pkgIndex.tcl
# fix for linking against shared lib with -lBLT or -lBLTlite
dosym libBLT24.so /usr/$(get_libdir)/libBLT.so || die
dosym libBLTlite24.so /usr/$(get_libdir)/libBLTlite.so || die
}
|
GitWeb