dev-ruby/ruby-openid/ruby-openid-2.2.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/ruby-openid/ruby-openid-2.2.0.ebuild,v 1.3 2012/10/17 03:53:20 phajdan.jr Exp $

EAPI="2"
USE_RUBY="ruby18 ruby19 jruby"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_TASK_TEST=""

RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md NOTICE UPGRADE.md"

inherit ruby-fakegem

DESCRIPTION="A robust library for verifying and serving OpenID identities"
HOMEPAGE="http://ruby-openid.rubyforge.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~ppc x86 ~x86-macos"
IUSE="test"

all_ruby_prepare() {
	# Comment out test failing due to hash ordering randomization:
	# https://github.com/openid/ruby-openid/issues/34
	rm test/test_xrires.rb || die

	sed -i -e 's/127.0.0.1/localhost/' test/test_fetchers.rb || die
	sed -i -e '134i :BindAddress => "localhost",' test/test_fetchers.rb || die
}

each_ruby_test() {
	${RUBY} -Ctest -I.:../lib -e "Dir['test_*.rb'].each {|f| require f}" || die
}

all_ruby_install() {
	all_fakegem_install

	insinto /usr/share/doc/${PF}
	doins -r examples || die
}