dev-python/zsi/zsi-2.1_alpha1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/zsi/zsi-2.1_alpha1.ebuild,v 1.3 2010/05/25 21:01:39 angelos Exp $

EAPI=2
PYTHON_DEPEND="2:2.4"
inherit distutils

MY_PN=ZSI
MY_P=${MY_PN}-${PV/_alpha/-a}

DESCRIPTION="Web Services for Python"
HOMEPAGE="http://pywebsvcs.sourceforge.net/zsi.html"
SRC_URI="mirror://sourceforge/pywebsvcs/${MY_P}.tar.gz"

KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"
LICENSE="PYTHON"
IUSE="examples doc twisted"

DEPEND=">=dev-python/pyxml-0.8.3
	>=dev-python/setuptools-0.6_rc7-r1
	twisted? ( >=dev-python/twisted-2
		>=dev-python/twisted-web-0.5 )"

S=${WORKDIR}/${MY_P}
PYTHON_MODNAME=${MY_PN}

pkg_setup() {
	python_set_active_version 2
}

src_prepare() {
	if ! use twisted; then
		sed -i \
			-e "/version_info/d"\
			-e "/ZSI.twisted/d"\
			setup.py || die "sed failed"
	fi
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml doc/*.{html,css,png}
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r doc/examples/* samples/*
	fi
}

DOCS="CHANGES README"