dev-python/pyftpdlib/pyftpdlib-0.6.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pyftpdlib/pyftpdlib-0.6.0.ebuild,v 1.4 2011/06/18 07:46:47 hwoarang Exp $

EAPI=3
PYTHON_DEPEND="2"
PYTHON_USE_WITH="ssl"
PYTHON_USE_WITH_OPT="ssl"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.*"

inherit distutils

DESCRIPTION="Python FTP server library"
HOMEPAGE="http://code.google.com/p/pyftpdlib/ http://pypi.python.org/pypi/pyftpdlib"
SRC_URI="http://pyftpdlib.googlecode.com/files/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~arm x86"
IUSE="examples ssl"

DEPEND="ssl? (
	dev-lang/python:2.7
	dev-python/pyopenssl
)"
RDEPEND="${DEPEND}"

DOCS="CREDITS HISTORY"

src_test() {
	testing() {
		PYTHONPATH="build-${PYTHON_ABI}/lib" "$(PYTHON)" test/test_ftpd.py \
			|| return 1
		PYTHONPATH="build-${PYTHON_ABI}/lib" "$(PYTHON)" test/test_contrib.py \
			|| return 1
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install
	dohtml -r doc/* || die
	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r demo test
	fi
}