dev-python/nevow/nevow-0.9.31.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/nevow/nevow-0.9.31.ebuild,v 1.6 2009/03/21 16:55:00 patrick Exp $

NEED_PYTHON="2.4"

inherit distutils multilib

MY_P="Nevow-${PV}"

DESCRIPTION="A web templating framework that provides LivePage, an automatic AJAX toolkit."
HOMEPAGE="http://divmod.org/trac/wiki/DivmodNevow"
SRC_URI="mirror://gentoo/${MY_P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 ~ia64 ~ppc ~sparc x86"
IUSE="doc"

RDEPEND=">=dev-python/twisted-2.5
	>=dev-python/twisted-web-8.1.0
	net-zope/zopeinterface"
DEPEND="${RDEPEND}
	doc? ( dev-python/docutils )"

S="${WORKDIR}/${MY_P}"

PYTHON_MODNAME="nevow formless"

src_compile() {
	distutils_src_compile
	if use doc; then
		cd doc
		"${python}" make.py || die "documentation building failed"
	fi
}

src_install() {
	distutils_src_install
	# mantisia expects js to be under site-packages/
	# but setup.py doesn't install it
	python_version
	insinto /usr/$(get_libdir)/python${PYVER}/site-packages/${PN}
	doins ${PN}/*.js || die "doins failed"
	doins -r ${PN}/js || die "doins failed"
	if use doc; then
		insinto /usr/share/doc/${PF}/
		doins -r doc/txt doc/html examples
	fi
}

src_test() {
	PYTHONPATH="." trial nevow || die "nevow trial failed"
	PYTHONPATH="." trial formless || die "formless trial failed"
}