dev-perl/Eidetic/Eidetic-2.003003-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-perl/Eidetic/Eidetic-2.003003-r1.ebuild,v 1.2 2014/04/26 10:28:40 zlogene Exp $

EAPI=5

inherit perl-module webapp eutils

DESCRIPTION="Templatized web-based database viewer, editor, indexer, etc"
HOMEPAGE="http://eidetic.sourceforge.net/"
SRC_URI="mirror://sourceforge/eidetic/${P}.tar.gz"

LICENSE="Artistic"
KEYWORDS="amd64 x86"
IUSE="doc mysql auth"

DEPEND="dev-lang/perl
		>=dev-perl/Config-Simple-4.1
		>=dev-perl/DBI-1.03
		>=virtual/perl-File-Temp-0.12
		>=virtual/perl-Digest-MD5-2.09
		>=virtual/perl-CGI-2.56
		virtual/perl-File-Spec
		>=dev-perl/Mail-Sender-0.8
		>=dev-perl/Sort-Tree-1.07
		>=dev-perl/Template-Toolkit-2.08
		dev-perl/Crypt-SmbHash
		mysql? ( virtual/mysql )
		auth? ( dev-perl/Apache-AuthTicket )"

# This appears required
MAKEOPTS="${MAKEOPTS} -j1"
# Tests require invocation of a local mysql server

PATCHES=( "${FILESDIR}"/${P}-destdir.patch \
	"${FILESDIR}"/${P}-sql.patch )

src_install() {
	# explicit inherit function calls
	perl-module_src_install
	webapp_src_preinst

	# install .cgi file
	insinto ${MY_CGIBINDIR}
	doins cgi-bin/eidetic.cgi

	# install documentation
	if use doc; then
		docompress -x usr/share/doc/${PF}/txt
		insinto usr/share/doc/${PF}/txt
		doins doc/*
	fi

	# install db creation scripts
	if use mysql
	then
		insinto /usr/share/${P}/sql
		doins sql/*
		fperms a+x /usr/share/${P}/sql/load_db.sh
	fi

	#webapp stuff
	webapp_src_install
}

pkg_postinst() {
	if use mysql; then
		elog "The SQL scripts for ${PN} are located in /usr/share/${P}/sql."
		elog "Use load_db.sh to create your initial database."
		elog "Please note this must be ran as a user with database creation"
		elog "priviliges."
		elog ""
	fi

	if use auth; then
		elog "The README file contains important information on setting up"
		elog "cookie authorization with Apache-AuthTicket.  Please be sure"
		elog "to read it!"
	fi
}