blob: 4c7acf43f04f6202f5fbb1252bb2b14270809cca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/redland/redland-1.0.15.ebuild,v 1.5 2012/03/05 21:14:01 maekke Exp $
EAPI=4
inherit libtool
DESCRIPTION="High-level interface for the Resource Description Framework"
HOMEPAGE="http://librdf.org/"
SRC_URI="http://download.librdf.org/source/${P}.tar.gz"
LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 arm hppa ppc ppc64 x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos"
IUSE="berkdb iodbc mysql odbc postgres sqlite ssl static-libs +xml"
# NOTE: libtool is required for libltdl at runtime
RDEPEND=">=sys-devel/libtool-2.2.6b
mysql? ( virtual/mysql )
sqlite? ( =dev-db/sqlite-3* )
berkdb? ( sys-libs/db )
xml? ( dev-libs/libxml2 )
!xml? ( dev-libs/expat )
ssl? ( dev-libs/openssl )
media-libs/raptor:2[xml?]
>=dev-libs/rasqal-0.9.26
postgres? ( dev-db/postgresql-base )
iodbc? ( dev-db/libiodbc )
odbc? ( dev-db/unixODBC )"
DEPEND="${RDEPEND}
dev-util/pkgconfig"
src_prepare() {
elibtoolize # NOTE: this is for fbsd .so version
}
src_configure() {
local parser=expat
use xml && parser=libxml
local myconf="--without-virtuoso"
if use iodbc; then
myconf="--with-virtuoso --with-iodbc --without-unixodbc"
elif use odbc; then
myconf="--with-virtuoso --with-unixodbc --without-iodbc"
fi
# FIXME: upstream doesn't test with --with-threads and testsuite fails
econf \
$(use_enable static-libs static) \
$(use_with berkdb bdb) \
--with-xml-parser=${parser} \
$(use_with ssl openssl-digests) \
$(use_with mysql) \
$(use_with sqlite) \
$(use_with postgres postgresql) \
--without-threads \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
${myconf}
}
src_test() {
if ! use berkdb; then
export REDLAND_TEST_CLONING_STORAGE_TYPE=hashes
export REDLAND_TEST_CLONING_STORAGE_NAME=test
export REDLAND_TEST_CLONING_STORAGE_OPTIONS="hash-type='memory',dir='.',write='yes',new='yes',contexts='yes'"
fi
default
}
src_install() {
default
dohtml {FAQS,NEWS,README,RELEASE,TODO}.html
find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
}
|
GitWeb
