dev-libs/libcdio/libcdio-0.83.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcdio/libcdio-0.83.ebuild,v 1.10 2012/03/08 14:53:57 ranger Exp $

EAPI=4

inherit autotools-utils

DESCRIPTION="A library to encapsulate CD-ROM reading and control"
HOMEPAGE="http://www.gnu.org/software/libcdio/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm hppa ~ia64 ppc ppc64 ~sh ~sparc x86 ~sparc-fbsd ~x86-fbsd"
IUSE="cddb +cxx minimal static-libs"

RDEPEND="cddb? ( >=media-libs/libcddb-1.0.1 )
	>=sys-libs/ncurses-5.7-r7
	virtual/libintl"
DEPEND="${RDEPEND}
	sys-devel/gettext
	dev-util/pkgconfig"

AUTOTOOLS_IN_SOURCE_BUILD=1

DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )

src_configure() {
	local myeconfargs=(
		$(use_enable cddb)
		$(use_enable cxx)
		$(use_with !minimal cd-drive)
		$(use_with !minimal cd-info)
		$(use_with !minimal cd-paranoia)
		$(use_with !minimal cdda-player)
		$(use_with !minimal cd-read)
		$(use_with !minimal iso-info)
		$(use_with !minimal iso-read)
		--disable-example-progs
		--disable-cpp-progs
		--with-cd-paranoia-name=libcdio-paranoia
		--disable-vcd-info
		--disable-maintainer-mode
	)
	autotools-utils_src_configure
}

pkg_postinst() {
	ewarn "If you've upgraded from a previous version of ${PN}, you may need to re-emerge"
	ewarn "packages that linked against ${PN} (vlc, vcdimager and more) by running:"
	ewarn "\trevdep-rebuild"
}