dev-libs/glib/glib-2.8.6.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.8.6.ebuild,v 1.2 2006/03/13 15:05:24 gustavoz Exp $

inherit gnome.org libtool eutils flag-o-matic debug

DESCRIPTION="The GLib library of C routines"
HOMEPAGE="http://www.gtk.org/"

LICENSE="LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc-macos ~ppc64 ~s390 ~sh sparc ~x86"
IUSE="debug doc hardened"

RDEPEND="virtual/libc
		 >=sys-devel/gettext-0.11"

DEPEND="${RDEPEND}
		>=dev-util/pkgconfig-0.14
		doc?	(
					>=dev-util/gtk-doc-1.4
					~app-text/docbook-xml-dtd-4.1.2
				)"


src_unpack() {
	unpack ${A}
	cd ${S}

	if use ppc64 && use hardened; then
		replace-flags -O[2-3] -O1
		epatch ${FILESDIR}/glib-2.6.3-testglib-ssp.patch
	fi

	epatch ${FILESDIR}/${PN}-2.8.3-macos.patch
}

src_compile() {
	epunt_cxx
	elibtoolize

	local myconf="--with-threads=posix $(use_enable doc gtk-doc)"

	# --disable-debug is not recommended for production use
	use debug && myconf="${myconf} --enable-debug=yes"

	econf $myconf || die "configure failed"
	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die "Installation failed"

	# Do not install charset.alias for ppc-macos since it already exists.
	if use ppc-macos ; then
		einfo "Not installing charset.alias on macos"
		rm ${D}/usr/lib/charset.alias || die "Cannot remove charset.alias from the image"
	fi

	# Consider invalid UTF-8 filenames as locale-specific.
	# FIXME : we should probably move to suggesting G_FILENAME_ENC
	dodir /etc/env.d
	echo "G_BROKEN_FILENAMES=1" > ${D}/etc/env.d/50glib2

	dodoc AUTHORS ChangeLog* NEWS* README
}