dev-java/nailgun/nailgun-0.7.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/nailgun/nailgun-0.7.1.ebuild,v 1.3 2009/08/08 21:26:32 mr_bones_ Exp $

EAPI="2"

JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2

DESCRIPTION="a client, protocol, and server for running Java apps without incurring the JVM startup overhead"
HOMEPAGE="http://martiansoftware.com/nailgun/index.html"
SRC_URI="mirror://sourceforge/${PN}/${PN}-src-${PV}.zip"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE=""

RDEPEND=">=virtual/jre-1.4"
DEPEND=">=virtual/jdk-1.4
	dev-java/java-getopt:1
	dev-java/bcel:0
	dev-java/jakarta-oro:2.0
	dev-java/log4j:0
	app-arch/unzip
	test? (
		dev-java/junit:0
		dev-java/ant-junit:0
	)"

#need jcoverage
RESTRICT="test"

java_prepare() {
	rm -vf ng* beansh
	find . -iname '*.jar' -delete

	epatch "${FILESDIR}/${PV}-Makefile.patch"

	sed -i '/<arg line="ng.exe/d' build.xml || die
	sed -i 's/depends="test"/depends="compile"/' build.xml || die

	java-pkg_jar-from --into tools/lib --build-only java-getopt-1 \
		gnu.getopt.jar java-getopt-1.0.10.jar
	java-pkg_jar-from --into tools/lib --build-only junit junit.jar
	java-pkg_jar-from --into tools/lib --build-only bcel bcel.jar \
		bcel-5.1.jar
	java-pkg_jar-from --into tools/lib --build-only jakarta-oro-2.0 \
		jakarta-oro.jar jakarta-oro-2.0.8.jar
	java-pkg_jar-from --into tools/lib --build-only log4j log4j.jar \
		log4j-1.2.8.jar
}

src_test() {
	WANT_TASKS="ant-junit" eant test
}

src_install() {
	dobin ng
	# Should we have a dolauncher?

	java-pkg_newjar "dist/${P}.jar"
	use doc && java-pkg_dojavadoc docs/api
	use source && java-pkg_dosrc src/java/prod/*
}