dev-java/bcel/bcel-5.1-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/bcel/bcel-5.1-r2.ebuild,v 1.1 2005/11/13 21:27:29 compnerd Exp $

inherit java-pkg eutils

DESCRIPTION="The Byte Code Engineering Library: analyze, create, manipulate Java class files"
HOMEPAGE="http://jakarta.apache.org/bcel/"
SRC_URI="mirror://apache/jakarta/bcel/source/${P}-src.tar.gz"
LICENSE="Apache-1.1"
SLOT="0"
KEYWORDS="x86 ppc sparc amd64 ppc64"
IUSE="doc jikes source"
RDEPEND=">=virtual/jre-1.3
	=dev-java/jakarta-regexp-1.3*"
DEPEND=">=virtual/jdk-1.3
	app-arch/unzip
	dev-java/ant-core
	jikes? ( dev-java/jikes )
	source? ( app-arch/zip )
	${RDEPEND}"

src_unpack() {
	unpack ${A}
	unzip -q "${P}-src.zip" || die "failed to unpack"

	cd ${S}
	epatch ${FILESDIR}/${P}-gentoo-buildxml-r2.diff
	epatch ${FILESDIR}/${P}-gentoo-src.diff

	echo "regexp.jar=$(java-pkg_getjars jakarta-regexp-1.3)" > build.properties
}

src_compile() {
	local antflags="jar"
	use doc && antflags="${antflags} apidocs"
	use jikes && antflags="${antflags} -Dbuild.compiler=jikes"
	ant ${antflags} || die "compilation failed"
}

src_install() {
	java-pkg_dojar bin/bcel.jar

	if use doc; then
		dodoc LICENSE.txt
		java-pkg_dohtml -r docs/
	fi
	use source && java-pkg_dosrc src/java/*
}