dev-embedded/dc-tool-ip/dc-tool-ip-1.0.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/dc-tool-ip/dc-tool-ip-1.0.4.ebuild,v 1.5 2013/04/15 21:24:53 vapier Exp $

EAPI="4"

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="ethernet program loader for the Dreamcast"
HOMEPAGE="http://cadcdev.sourceforge.net/"
SRC_URI="mirror://sourceforge/cadcdev/dcload-ip-${PV}-src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="doc"

S=${WORKDIR}/dcload-ip-${PV}

src_prepare() {
	epatch "${FILESDIR}"/${PV}-bfd-update.patch
	epatch "${FILESDIR}"/${P}-headers.patch
	append-cppflags -DPACKAGE -DPACKAGE_VERSION #465952
	sed -i \
		-e "/^HOSTCC/s:gcc:$(tc-getCC):" \
		-e "/^HOSTCFLAGS/s:-O2:${CFLAGS} ${CPPFLAGS}:" \
		-e 's:-L/usr/local/dcdev/lib:$(LDFLAGS):' \
		-e 's:/usr/local/dcdev/include:.:' \
		Makefile.cfg || die "sed"
}

src_compile() {
	emake -C host-src/tool
}

src_install() {
	dobin host-src/tool/dc-tool
	dodoc README NETWORK CHANGES
	dodoc -r make-cd
	if use doc ; then
		dodoc -r example-src
	fi
}