blob: 4defa63d98d62124d417e8f2ae7b6c8383ac5e52 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/task/task-2.0.0_rc1.ebuild,v 1.1 2012/03/06 10:19:04 radhermit Exp $
EAPI=4
inherit eutils cmake-utils bash-completion-r1
MY_P="${P/_rc/.RC}"
DESCRIPTION="A task management tool with a command-line interface"
HOMEPAGE="http://taskwarrior.org/projects/show/taskwarrior/"
SRC_URI="http://taskwarrior.org/download/${MY_P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="lua vim-syntax zsh-completion"
DEPEND="lua? ( dev-lang/lua )"
RDEPEND="${DEPEND}"
S="${WORKDIR}/${MY_P}"
src_prepare() {
# Use the correct directory locations
sed -i -e "s:/usr/local/share/doc/task/rc:/usr/share/task/rc:" \
doc/man/taskrc.5.in doc/man/task-tutorial.5.in doc/man/task-color.5.in || die
sed -i -e "s:/usr/local/bin:/usr/bin:" doc/man/task-faq.5.in scripts/add-ons/* || die
# Don't automatically install scripts
sed -i -e '/scripts/d' CMakeLists.txt || die
epatch "${FILESDIR}"/${PN}-2.0.0_beta4-rcdir.patch
epatch "${FILESDIR}"/${PN}-1.9.4-lua-automagic.patch
}
src_configure() {
mycmakeargs=(
$(cmake-utils_use_enable lua LUA)
-DTASK_DOCDIR=/usr/share/doc/${PF}
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
newbashcomp scripts/bash/task_completion.sh task
if use vim-syntax ; then
rm scripts/vim/README
insinto /usr/share/vim/vimfiles
doins -r scripts/vim/*
fi
if use zsh-completion ; then
insinto /usr/share/zsh/site-functions
doins scripts/zsh/*
fi
exeinto /usr/share/${PN}/scripts
doexe scripts/add-ons/*
}
|
GitWeb
