app-misc/g15composer/g15composer-2.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/g15composer/g15composer-2.1-r1.ebuild,v 1.1 2006/10/31 22:42:27 jokey Exp $

inherit eutils

DESCRIPTION="A library to render text and shapes into a buffer usable by the Logitech G15 keyboard"
HOMEPAGE="http://g15tools.sourceforge.net/"
SRC_URI="mirror://sourceforge/g15tools/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="amarok truetype"

RDEPEND="app-misc/g15daemon
	dev-libs/libg15render
	truetype? ( media-libs/freetype )
	amarok? ( kde-base/kdelibs  dev-perl/DCOP-Amarok-Player )"

DEPEND="${RDEPEND}
	dev-libs/libg15"

pkg_setup() {
	if use amarok && ! built_with_use dev-lang/perl ithreads ; then
		echo
		eerror "dev-lang/perl must be built with USE=\"ithreads\" for the Amarok display to work."
		die
	fi
}

src_compile() {
	econf \
		$(use_enable truetype ttf ) \
		|| die "configure failed"

	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	newinitd "${FILESDIR}/${P}.initd" ${PN}
	newconfd "${FILESDIR}/${P}.confd" ${PN}

	dodoc AUTHORS README ChangeLog

	exeinto "${ROOT}usr/share/${PN}"
	doexe examples/*

	if use amarok ; then
		exeinto "${ROOT}usr/share/apps/amarok/scripts"
		newexe examples/amarok-g15-perl.pl g15-display.pl
	fi
}

pkg_postinst() {
	if use amarok; then
		einfo "g15-display.pl was installed into your Amarok script directory."
		einfo "To start it, have a look at Tools -> Script Manager in the Amarok menu."
	fi
}