blob: 915bbc091fbc4134ca42aa73b3877c32ed5b0af1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.5.1-r2.ebuild,v 1.2 2013/04/05 03:54:15 naota Exp $
EAPI=4
PYTHON_DEPEND="python? 2:2.5"
VALA_MIN_API_VERSION="0.18"
VALA_USE_DEPEND="vapigen"
# Vapigen is needed for the vala binding
# Valac is needed when building from git for the engine
inherit eutils gnome2-utils multilib python vala virtualx
DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
HOMEPAGE="http://code.google.com/p/ibus/"
SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
# USE=vala and DEPEND=gnome-base/gconf is temporaly removed due to fix patch:
# ${P}-use-system-keyboard-layout.patch
IUSE="dconf deprecated +gconf gtk +gtk3 +introspection nls +python test +X"
REQUIRED_USE="|| ( gtk gtk3 X )
deprecated? ( python )
python? ( || ( deprecated ( gtk3 introspection ) ) )" #342903
COMMON_DEPEND=">=dev-libs/glib-2.26:2
gnome-base/librsvg:2
sys-apps/dbus[X?]
app-text/iso-codes
dconf? ( >=gnome-base/dconf-0.13.4 )
gconf? ( >=gnome-base/gconf-2.12:2 )
gtk? ( x11-libs/gtk+:2 )
gtk3? ( x11-libs/gtk+:3 )
X? (
x11-libs/libX11
x11-libs/gtk+:2 )
introspection? ( >=dev-libs/gobject-introspection-0.6.8 )
nls? ( virtual/libintl )"
RDEPEND="${COMMON_DEPEND}
python? (
dev-python/pyxdg
deprecated? (
>=dev-python/dbus-python-0.83
dev-python/pygobject:2
dev-python/pygtk:2 )
gtk3? (
dev-python/pygobject:3
x11-libs/gdk-pixbuf:2[introspection]
x11-libs/pango[introspection]
x11-libs/gtk+:3[introspection] )
)"
DEPEND="${COMMON_DEPEND}
>=dev-lang/perl-5.8.1
dev-util/gtk-doc-am
dev-util/intltool
virtual/pkgconfig
nls? ( >=sys-devel/gettext-0.16.1 )
$(vala_depend)
gnome-base/gconf"
# stress test in bus/ fails
# IBUS-CRITICAL **: bus_test_client_init: assertion `ibus_bus_is_connected (_bus)' failed
RESTRICT="test"
DOCS="AUTHORS ChangeLog NEWS README"
pkg_setup() {
if use python; then
python_set_active_version 2
python_pkg_setup
fi
}
src_prepare() {
# We run "dconf update" in pkg_postinst/postrm to avoid sandbox violations
sed -e 's/dconf update/$(NULL)/' \
-i data/dconf/Makefile.{am,in} || die
use python && python_clean_py-compile_files
vala_src_prepare
epatch "${FILESDIR}"/${P}-setup.patch \
"${FILESDIR}"/${P}-queue-events.patch \
"${FILESDIR}"/${P}-use-system-keyboard-layout.patch
cp "${S}"/client/gtk2/ibusimcontext.c "${S}"/client/gtk3/ibusimcontext.c || die
}
src_configure() {
local python_conf
if use python; then
# We cannot call $(PYTHON) if we haven't called python_pkg_setup
python_conf="PYTHON=$(PYTHON)
$(use_enable deprecated python-library)
$(use_enable gtk3 setup)"
else
python_conf="--disable-python-library --disable-setup"
fi
econf \
$(use_enable dconf) \
$(use_enable introspection) \
$(use_enable gconf) \
$(use_enable gtk gtk2) \
$(use_enable gtk xim) \
$(use_enable gtk3) \
$(use_enable gtk3 ui) \
$(use_enable nls) \
$(use_enable test tests) \
$(use_enable X xim) \
--enable-vala \
${python_conf}
}
src_test() {
unset DBUS_SESSION_BUS_ADDRESS
Xemake check || die
}
src_install() {
default
find "${ED}" -name '*.la' -exec rm -f {} +
insinto /etc/X11/xinit/xinput.d
newins xinput-ibus ibus.conf
keepdir /usr/share/ibus/{engine,icons} #289547
}
pkg_preinst() {
use gconf && gnome2_gconf_savelist
gnome2_icon_savelist
}
pkg_postinst() {
if use dconf; then
ebegin "Updating dconf system databases"
dconf update
eend $?
fi
use gconf && gnome2_gconf_install
use gtk && gnome2_query_immodules_gtk2
use gtk3 && gnome2_query_immodules_gtk3
use deprecated && python_mod_optimize ${PN}
use python && use gtk3 && python_mod_optimize /usr/share/${PN}
gnome2_icon_cache_update
elog "To use ibus, you should:"
elog "1. Get input engines from sunrise overlay."
elog " Run \"emerge -s ibus-\" in your favorite terminal"
elog " for a list of packages we already have."
elog
elog "2. Setup ibus:"
elog
elog " $ ibus-setup"
elog
elog "3. Set the following in your user startup scripts"
elog " such as .xinitrc, .xsession or .xprofile:"
elog
elog " export XMODIFIERS=\"@im=ibus\""
elog " export GTK_IM_MODULE=\"ibus\""
elog " export QT_IM_MODULE=\"xim\""
elog " ibus-daemon -d -x"
}
pkg_postrm() {
if use dconf; then
ebegin "Updating dconf system databases"
dconf update
eend $?
fi
use gtk && gnome2_query_immodules_gtk2
use gtk3 && gnome2_query_immodules_gtk3
use deprecated && python_mod_cleanup ${PN}
use python && use gtk3 && python_mod_cleanup /usr/share/${PN}
gnome2_icon_cache_update
}
|
GitWeb