app-emacs/slime/slime-0.13.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/slime/slime-0.13.ebuild,v 1.7 2004/11/07 06:20:55 mr_bones_ Exp $

inherit elisp

DESCRIPTION="SLIME: The Superior Lisp Interaction Mode for Emacs"
HOMEPAGE="http://common-lisp.net/project/slime/"
SRC_URI="mirror://gentoo/${P}.tar.bz2"
LICENSE="|| ( GPL-2 public-domain LLGPL-2.1 )"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE=""

DEPEND="virtual/emacs
	dev-lisp/common-lisp-controller
	virtual/commonlisp"

CLPACKAGE=swank

src_compile() {
	echo "(add-to-list 'load-path \".\")" >script
	emacs --batch -q -l script -f batch-byte-compile hyperspec.el slime.el || die
}

src_install() {
	elisp-install ${PN} hyperspec.el slime.el slime.elc ${FILESDIR}/swank-loader.lisp
	elisp-site-file-install ${FILESDIR}/70slime-gentoo.el
	dodoc README* ChangeLog
	insinto /usr/share/common-lisp/source/swank
	# ChangeLog is needed at compile time!!
	doins *.lisp ${FILESDIR}/swank.asd ChangeLog
	dodir /usr/share/common-lisp/systems
	dosym /usr/share/common-lisp/source/swank/swank.asd \
		/usr/share/common-lisp/systems
}

pkg_preinst() {
	rm -rf /usr/lib/common-lisp/*/${CLPACKAGE} || true
}

pkg_postrm() {
	rm -rf /usr/lib/common-lisp/*/${CLPACKAGE} || true
	elisp-site-regen
}

pkg_postinst() {
	/usr/sbin/register-common-lisp-source ${CLPACKAGE}
	elisp-site-regen
	while read line; do einfo "${line}"; done <<EOF

SLIME notes for Gentoo
----------------------

Gentoo's port for SLIME uses its own swank.asd so that it fits more
cleanly into the Gentoo Common Lisp Controller framework.  For this
reason, DO NOT report problems to SLIME's upstream authors.	 Always
report problems to the Gentoo Bugzilla at http://bugs.gentoo.org
unless you are absolutely certain your problem it is not related to
the Gentoo port of SLIME.

Matthew Kennedy <mkennedy@gentoo.org>

EOF
}