app-editors/jed/jed-0.99.19.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/jed/jed-0.99.19.ebuild,v 1.6 2010/05/23 18:20:09 pacho Exp $

EAPI=3

inherit versionator

MY_P=${PN}-$(replace_version_separator 2 '-')
DESCRIPTION="Console S-Lang-based editor"
HOMEPAGE="http://www.jedsoft.org/jed/"
SRC_URI="ftp://space.mit.edu/pub/davis/jed/v0.99/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x86-macos"
IUSE="X gpm xft"

RDEPEND=">=sys-libs/slang-2
	X? ( x11-libs/libX11
		xft? ( x11-libs/libXext
			x11-libs/libXft
			x11-libs/libXrender
			>=media-libs/freetype-2.0 ) )
	gpm? ( sys-libs/gpm )"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${MY_P}"

src_configure() {
	export JED_ROOT="${EPREFIX}/usr/share/jed"
	econf \
		$(use_enable gpm) \
		$(use_enable xft)
}

src_compile() {
	emake || die
	if use X; then
		emake xjed || die
	fi
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die

	dodoc INSTALL INSTALL.unx README changes.txt || die
	doinfo info/jed* || die

	insinto /etc
	doins lib/jed.conf || die

	# replace IDE mode with EMACS mode
	sed -i -e 's/\(_Jed_Default_Emulation = \).*/\1"emacs";/' \
		"${ED}"/etc/jed.conf || die "patching jed.conf failed"
}