app-crypt/scl011-bin/scl011-bin-2.06.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/scl011-bin/scl011-bin-2.06.ebuild,v 1.3 2012/07/30 05:02:06 flameeyes Exp $

EAPI=4

inherit multilib toolchain-funcs

DESCRIPTION="pcsc-lite driver for the German identification card (nPA)"
HOMEPAGE="http://www.scmmicro.com/de/products-services/chipkartenleser-terminals/kontaktlos-dual-interface/it-sicherheitskit-basisleser/treiber.html"
SRC_URI="x86? ( http://www.scmmicro.com/npa/files/scl011_${PV}_linux_32bit.tar.gz )
	amd64? ( http://www.scmmicro.com/npa/files/scl011_${PV}_linux_64bit.tar.gz )"

LICENSE="SCM-MICRO"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE=""

RDEPEND="sys-apps/pcsc-lite"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S="${WORKDIR}"

RESTRICT="mirror bindist"

QA_PREBUILT="*/libSCL011.so.2.06"

src_install() {
	local INSTALL_DIR=`$(tc-getPKG_CONFIG) libpcsclite --variable=usbdropdir`
	local BASEPATH
	case $(tc-arch) in
		amd64) BASEPATH="${S}/scl011_${PV}_linux_64bit" ;;
		x86)   BASEPATH="${S}/scl011_${PV}_linux_32bit" ;;
	esac

	insinto "${INSTALL_DIR}"/SCL011.bundle/Contents
	doins "${BASEPATH}"/proprietary/SCL011.bundle/Contents/Info.plist
	exeinto "${INSTALL_DIR}"/SCL011.bundle/Contents/Linux
	doexe "${BASEPATH}"/proprietary/SCL011.bundle/Contents/Linux/libSCL011.so.${PV}

	insinto /$(get_libdir)/udev/rules.d
	doins "${FILESDIR}"/92_pcscd_scl011-bin.rules
}