app-accessibility/brltty/brltty-3.7.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-accessibility/brltty/brltty-3.7.2-r1.ebuild,v 1.6 2007/07/31 02:28:33 williamh Exp $

inherit eutils multilib toolchain-funcs

DESCRIPTION="Daemon that provides access to the Linux/Unix console for a blind person"
HOMEPAGE="http://mielke.cc/brltty/"
SRC_URI="http://mielke.cc/brltty/releases/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
IUSE="doc gpm usb X"

DEPEND=" gpm? ( >=sys-libs/gpm-1.20 )
	X? ( x11-libs/libXaw )"

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch "${FILESDIR}"/${P}-nostrip.patch
	epatch "${FILESDIR}"/${P}-linux-compiler-h.patch
}

src_compile() {
	econf $(use_enable gpm) \
		$(use_with X x) \
		$(use_enable usb usb-support) \
		--prefix=/ \
		--includedir=/usr/include || die
	make || die
}

src_install() {
	make INSTALL_ROOT=${D} install || die
	TMPDIR=../../Programs scanelf -RBXr ${D} -o /dev/null
	libdir="$(get_libdir)"
	mkdir -p ${D}/usr/${libdir}/
	mv ${D}/${libdir}/*.a ${D}/usr/${libdir}/
	gen_usr_ldscript libbrlapi.so
	cd Documents
	rm *.made
	dodoc ChangeLog README* Manual.* TODO brltty.conf
	dohtml -r Manual-HTML
	newinitd ${FILESDIR}/brltty.rc brltty
	if use doc; then
		dodoc BrlAPI.* BrlAPIref.doxy
		dohtml -r BrlAPI-HTML BrlAPIref-HTML
	fi
}

pkg_postinst() {
	elog
	elog There is a sample config file in /usr/share/doc/${P}/brltty.conf.
	elog To use this file, uncompress it into /etc/brltty
	elog
	elog To make brltty start on boot, type this command as root:
	elog
	elog rc-update add brltty boot
}