1 files changed, 58 insertions, 0 deletions
diff --git a/x11-misc/dmenu/dmenu-2.8.ebuild b/x11-misc/dmenu/dmenu-2.8.ebuild
new file mode 100644
index 000000000000..d7318e1e0b25
--- /dev/null
+++ b/x11-misc/dmenu/dmenu-2.8.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/dmenu/dmenu-2.8.ebuild,v 1.1 2007/03/07 19:14:21 cedk Exp $
+
+inherit toolchain-funcs savedconfig
+
+DESCRIPTION="a generic, highly customizable, and efficient menu for the X Window System"
+HOMEPAGE="http://tools.suckless.org/view.sh/x+tools"
+SRC_URI="http://suckless.org/download/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="x11-libs/libX11"
+RDEPEND=${DEPEND}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	sed -i \
+		-e "s/.*strip.*//" \
+		Makefile || die "sed failed"
+
+	sed -i \
+		-e "s/CFLAGS = -Os/CFLAGS +=/" \
+		-e "s/LDFLAGS =/LDFLAGS +=/" \
+		config.mk || die "sed failed"
+
+	if use savedconfig; then
+		restore_config ${PN}.h
+	fi
+}
+
+src_compile() {
+	local msg
+	use savedconfig && msg=", please check the configfile"
+	emake CC=$(tc-getCC) || die "emake failed${msg}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" install || die "emake install failed"
+
+	insinto /usr/share/${PN}
+	newins ${PN}.h ${PF}.config.h
+
+	dodoc README
+
+	save_config ${PN}.h
+}
+
+pkg_postinst() {
+	einfo "This ebuild has support for user defined configs"
+	einfo "Please read this ebuild for more details and re-emerge as needed"
+	einfo "if you want to add or remove functionality for ${PN}"
+}