1 files changed, 64 insertions, 0 deletions
diff --git a/x11-libs/qt-opengl/qt-opengl-4.8.4.ebuild b/x11-libs/qt-opengl/qt-opengl-4.8.4.ebuild
new file mode 100644
index 000000000000..19f7dedc8200
--- /dev/null
+++ b/x11-libs/qt-opengl/qt-opengl-4.8.4.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-opengl/qt-opengl-4.8.4.ebuild,v 1.1 2012/12/05 03:23:05 yngwin Exp $
+
+EAPI=4
+
+inherit qt4-build
+
+DESCRIPTION="The OpenGL module for the Qt toolkit"
+SLOT="4"
+if [[ ${QT4_BUILD_TYPE} == live ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+fi
+IUSE="egl qt3support"
+
+DEPEND="
+	virtual/opengl
+	~x11-libs/qt-core-${PV}[aqua=,debug=,qt3support=]
+	~x11-libs/qt-gui-${PV}[aqua=,debug=,egl=,qt3support=]
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	QT4_TARGET_DIRECTORIES="
+		src/opengl
+		src/plugins/graphicssystems/opengl"
+
+	QT4_EXTRACT_DIRECTORIES="
+		include/QtCore
+		include/QtGui
+		include/QtOpenGL
+		src/corelib
+		src/gui
+		src/opengl
+		src/plugins
+		src/3rdparty"
+
+	QCONFIG_ADD="opengl"
+	QCONFIG_DEFINE="QT_OPENGL"
+
+	qt4-build_pkg_setup
+}
+
+src_configure() {
+	myconf+="
+		-opengl
+		$(qt_use qt3support)
+		$(qt_use egl)"
+
+	qt4-build_src_configure
+
+	# Not building tools/designer/src/plugins/tools/view3d as it's
+	# commented out of the build in the source
+}
+
+src_install() {
+	qt4-build_src_install
+
+	# touch the available graphics systems
+	dodir /usr/share/qt4/graphicssystems
+	echo "experimental" > "${ED}"/usr/share/qt4/graphicssystems/opengl || die
+}