1 files changed, 47 insertions, 0 deletions
diff --git a/sys-devel/dragonegg/dragonegg-3.0_rc3.ebuild b/sys-devel/dragonegg/dragonegg-3.0_rc3.ebuild
new file mode 100644
index 000000000000..ad9d7c446164
--- /dev/null
+++ b/sys-devel/dragonegg/dragonegg-3.0_rc3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/dragonegg/dragonegg-3.0_rc3.ebuild,v 1.1 2011/11/10 12:35:56 voyageur Exp $
+
+EAPI=4
+inherit multilib
+
+DESCRIPTION="GCC plugin that uses LLVM for optimization and code generation"
+HOMEPAGE="http://dragonegg.llvm.org/"
+SRC_URI="http://llvm.org/pre-releases/${PV/_rc*}/${PV/3.0_}/${P/_}.src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND=">=sys-devel/gcc-4.5.0[lto]
+	~sys-devel/llvm-${PV}"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${P/_}.src
+
+src_prepare() {
+	# Remove in final 3.0
+	sed -e "s/\(^REVISION:=\).*/\1${P}/" \
+		-i Makefile || die "Setting revision failed"
+}
+
+src_compile() {
+	# GCC: compiler to use plugin with
+	emake CC="$(tc-getCC)" GCC="$(tc-getCC)" CXX="$(tc-getCXX)" VERBOSE=1
+}
+
+src_install() {
+	# Install plugin in llvm lib directory
+	exeinto /usr/$(get_libdir)/llvm
+	doexe dragonegg.so
+
+	dodoc README
+}
+
+pkg_postinst() {
+	elog "To use dragonegg, run gcc as usual, with an extra command line argument:"
+	elog "	-fplugin=/usr/$(get_libdir)/llvm/dragonegg.so"
+	elog "If you change the active gcc profile, or update gcc to a new version,"
+	elog "you will have to remerge this package to update the plugin"
+}