1 files changed, 65 insertions, 0 deletions
diff --git a/sys-apps/sed/sed-4.2.ebuild b/sys-apps/sed/sed-4.2.ebuild
new file mode 100644
index 000000000000..9b81d5dad242
--- /dev/null
+++ b/sys-apps/sed/sed-4.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/sed/sed-4.2.ebuild,v 1.1 2009/05/20 08:16:00 vapier Exp $
+
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="Super-useful stream editor"
+HOMEPAGE="http://sed.sourceforge.net/"
+SRC_URI="mirror://gnu/sed/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="nls static"
+
+RDEPEND="nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_bootstrap_sed() {
+	# make sure system-sed works #40786
+	export NO_SYS_SED=""
+	if ! type -p sed > /dev/null ; then
+		NO_SYS_SED="!!!"
+		./bootstrap.sh || die "couldnt bootstrap"
+		cp sed/sed "${T}"/ || die "couldnt copy"
+		export PATH="${PATH}:${T}"
+		make clean || die "couldnt clean"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${PN}-4.1.5-alloca.patch
+	# don't use sed here if we have to recover a broken host sed
+}
+
+src_compile() {
+	src_bootstrap_sed
+	# this has to be after the bootstrap portion
+	sed -i \
+		-e '/docdir =/s:=.*/doc:= $(datadir)/doc/'${PF}'/html:' \
+		doc/Makefile.in || die "sed html doc"
+
+	local myconf= bindir=/bin
+	if ! use userland_GNU ; then
+		myconf="--program-prefix=g"
+		bindir=/usr/bin
+	fi
+
+	use static && append-ldflags -static
+	econf \
+		--bindir=${bindir} \
+		$(use_enable nls) \
+		${myconf}
+	emake || die "build failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "Install failed"
+	dodoc NEWS README* THANKS AUTHORS BUGS ChangeLog
+	docinto examples
+	dodoc "${FILESDIR}"/{dos2unix,unix2dos}
+}