Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status
summaryrefslogtreecommitdiff
path: root/sci-libs
diff options
context:
space:
mode:
Diffstat (limited to 'sci-libs')
-rw-r--r--sci-libs/gdal/ChangeLog12
-rw-r--r--sci-libs/gdal/gdal-1.3.1.ebuild8
-rw-r--r--sci-libs/gdal/gdal-1.3.2.ebuild12
-rw-r--r--sci-libs/gdal/gdal-1.4.2.ebuild12
-rw-r--r--sci-libs/gdal/gdal-1.5.2.ebuild10
-rw-r--r--sci-libs/gdal/gdal-1.5.3.ebuild211
-rw-r--r--sci-libs/gdal/metadata.xml4
7 files changed, 250 insertions, 19 deletions
diff --git a/sci-libs/gdal/ChangeLog b/sci-libs/gdal/ChangeLog
index 83b7603de3c6..2c2e5eafb8ea 100644
--- a/sci-libs/gdal/ChangeLog
+++ b/sci-libs/gdal/ChangeLog
@@ -1,6 +1,16 @@
# ChangeLog for sci-libs/gdal
# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/ChangeLog,v 1.47 2008/10/12 14:21:06 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/ChangeLog,v 1.48 2008/10/18 19:08:36 nerdboy Exp $
+
+*gdal-1.5.3 (18 Oct 2008)
+
+ 18 Oct 2008; Steve Arnold <nerdboy@gentoo.org> metadata.xml,
+ gdal-1.5.2.ebuild, +gdal-1.5.3.ebuild:
+ Updated with latest release and fixes for the perllocal.pod thing and
+ USE flag support for libecwj2 (subject to blocking bug #230802). The
+ latter support is only in 1.5.3 so 1.5.2 should be fine (ie, with the
+ existing jasper support). Also fixed some minor QA issues in older
+ versions.
12 Oct 2008; nixnut <nixnut@gentoo.org> gdal-1.5.2.ebuild:
Stable on ppc wrt bug 241500
diff --git a/sci-libs/gdal/gdal-1.3.1.ebuild b/sci-libs/gdal/gdal-1.3.1.ebuild
index 9bc54e018c8d..af06c1e9f582 100644
--- a/sci-libs/gdal/gdal-1.3.1.ebuild
+++ b/sci-libs/gdal/gdal-1.3.1.ebuild
@@ -1,6 +1,6 @@
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.3.1.ebuild,v 1.17 2008/10/12 02:38:16 nerdboy Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.3.1.ebuild,v 1.18 2008/10/18 19:08:36 nerdboy Exp $
inherit eutils libtool distutils toolchain-funcs
@@ -17,7 +17,7 @@ KEYWORDS="amd64 ppc ppc64 sparc x86"
# need to get these arches updated on several libs first
#KEYWORDS="~alpha ~hppa"
-DEPEND=">=sys-libs/zlib-1.1.4
+RDEPEND=">=sys-libs/zlib-1.1.4
>=media-libs/tiff-3.7.0
sci-libs/libgeotiff
jpeg? ( media-libs/jpeg )
@@ -36,7 +36,9 @@ DEPEND=">=sys-libs/zlib-1.1.4
jpeg2k? ( media-libs/jasper )
odbc? ( dev-db/unixODBC )
geos? ( >=sci-libs/geos-2.2.1 )
- sqlite? ( >=dev-db/sqlite-3 )
+ sqlite? ( >=dev-db/sqlite-3 )"
+
+DEPEND="${RDEPEND}
doc? ( app-doc/doxygen )"
src_unpack() {
diff --git a/sci-libs/gdal/gdal-1.3.2.ebuild b/sci-libs/gdal/gdal-1.3.2.ebuild
index df0e7853a237..4218ac4c7a25 100644
--- a/sci-libs/gdal/gdal-1.3.2.ebuild
+++ b/sci-libs/gdal/gdal-1.3.2.ebuild
@@ -1,6 +1,6 @@
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.3.2.ebuild,v 1.7 2008/10/12 02:38:16 nerdboy Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.3.2.ebuild,v 1.8 2008/10/18 19:08:36 nerdboy Exp $
inherit eutils libtool distutils toolchain-funcs
@@ -17,15 +17,14 @@ KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
# need to get these arches updated on several libs first
#KEYWORDS="~alpha ~hppa"
-DEPEND=">=sys-libs/zlib-1.1.4
+RDEPEND=">=sys-libs/zlib-1.1.4
>=media-libs/tiff-3.7.0
sci-libs/libgeotiff
jpeg? ( media-libs/jpeg )
gif? ( media-libs/giflib )
png? ( media-libs/libpng )
python? ( dev-lang/python )
- ruby? ( >=dev-lang/ruby-1.8.4.20060226
- >=dev-lang/swig-1.3.28 )
+ ruby? ( >=dev-lang/ruby-1.8.4.20060226 )
fits? ( sci-libs/cfitsio )
ogdi? ( sci-libs/ogdi )
gml? ( <dev-libs/xerces-c-2.8.0 )
@@ -38,7 +37,10 @@ DEPEND=">=sys-libs/zlib-1.1.4
jpeg2k? ( media-libs/jasper )
odbc? ( dev-db/unixODBC )
geos? ( >=sci-libs/geos-2.2.1 )
- sqlite? ( >=dev-db/sqlite-3 )
+ sqlite? ( >=dev-db/sqlite-3 )"
+
+DEPEND="${RDEPEND}
+ ruby? ( >=dev-lang/swig-1.3.28 )
doc? ( app-doc/doxygen )"
src_unpack() {
diff --git a/sci-libs/gdal/gdal-1.4.2.ebuild b/sci-libs/gdal/gdal-1.4.2.ebuild
index aad09eb4efa4..ded2d03f92d4 100644
--- a/sci-libs/gdal/gdal-1.4.2.ebuild
+++ b/sci-libs/gdal/gdal-1.4.2.ebuild
@@ -1,6 +1,6 @@
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.4.2.ebuild,v 1.5 2008/10/12 02:38:16 nerdboy Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.4.2.ebuild,v 1.6 2008/10/18 19:08:36 nerdboy Exp $
inherit eutils libtool distutils toolchain-funcs
@@ -17,15 +17,14 @@ KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
# need to get these arches updated on several libs first
#KEYWORDS="~alpha ~hppa"
-DEPEND=">=sys-libs/zlib-1.1.4
+RDEPEND=">=sys-libs/zlib-1.1.4
>=media-libs/tiff-3.7.0
sci-libs/libgeotiff
jpeg? ( media-libs/jpeg )
gif? ( media-libs/giflib )
png? ( media-libs/libpng )
python? ( dev-lang/python )
- ruby? ( >=dev-lang/ruby-1.8.4.20060226
- >=dev-lang/swig-1.3.28 )
+ ruby? ( >=dev-lang/ruby-1.8.4.20060226 )
fits? ( sci-libs/cfitsio )
ogdi? ( sci-libs/ogdi )
gml? ( <dev-libs/xerces-c-2.8.0 )
@@ -39,7 +38,10 @@ DEPEND=">=sys-libs/zlib-1.1.4
mysql? ( virtual/mysql )
odbc? ( dev-db/unixODBC )
geos? ( >=sci-libs/geos-2.2.1 )
- sqlite? ( >=dev-db/sqlite-3 )
+ sqlite? ( >=dev-db/sqlite-3 )"
+
+DEPEND="${RDEPEND}
+ ruby? ( >=dev-lang/swig-1.3.28 )
doc? ( app-doc/doxygen )"
src_unpack() {
diff --git a/sci-libs/gdal/gdal-1.5.2.ebuild b/sci-libs/gdal/gdal-1.5.2.ebuild
index f1c7d4423151..7ba9dd0ef97a 100644
--- a/sci-libs/gdal/gdal-1.5.2.ebuild
+++ b/sci-libs/gdal/gdal-1.5.2.ebuild
@@ -1,12 +1,12 @@
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.5.2.ebuild,v 1.2 2008/10/12 14:21:06 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.5.2.ebuild,v 1.3 2008/10/18 19:08:36 nerdboy Exp $
WANT_AUTOCONF="2.5"
inherit autotools distutils eutils perl-module toolchain-funcs
-IUSE="curl debug doc fits geos gif gml hdf hdf5 jpeg jpeg2k mysql netcdf \
-odbc png ogdi perl postgres python ruby sqlite threads"
+IUSE="curl debug doc fits geos gif gml hdf hdf5 jpeg jpeg2k mysql \
+netcdf odbc png ogdi perl postgres python ruby sqlite threads"
DESCRIPTION="GDAL is a translator library for raster geospatial data formats (includes OGR support)"
HOMEPAGE="http://www.gdal.org/"
@@ -32,7 +32,7 @@ RDEPEND=">=sys-libs/zlib-1.1.4
ruby? ( >=dev-lang/ruby-1.8.4.20060226 )
fits? ( sci-libs/cfitsio )
ogdi? ( sci-libs/ogdi )
- gml? ( >=dev-libs/xerces-c-2.8.0 )
+ gml? ( =dev-libs/xerces-c-2.8* )
hdf5? ( >=sci-libs/hdf5-1.6.4 )
postgres? ( virtual/postgresql-server )
|| (
@@ -179,6 +179,8 @@ src_install() {
insinto /usr/share/${PN}/samples
doins swig/python/samples/*
fi
+
+ use perl && fixlocalpod
}
pkg_postinst() {
diff --git a/sci-libs/gdal/gdal-1.5.3.ebuild b/sci-libs/gdal/gdal-1.5.3.ebuild
new file mode 100644
index 000000000000..26666f51b87d
--- /dev/null
+++ b/sci-libs/gdal/gdal-1.5.3.ebuild
@@ -0,0 +1,211 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/gdal/gdal-1.5.3.ebuild,v 1.1 2008/10/18 19:08:36 nerdboy Exp $
+
+WANT_AUTOCONF="2.5"
+inherit autotools distutils eutils perl-module toolchain-funcs
+
+DESCRIPTION="GDAL is a translator library for raster geospatial data formats (includes OGR support)"
+HOMEPAGE="http://www.gdal.org/"
+SRC_URI="http://download.osgeo.org/gdal/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+# need to get these arches updated on several libs first
+#KEYWORDS="~alpha ~hppa"
+
+IUSE="curl debug doc ecwj2k fits geos gif gml hdf hdf5 jpeg jpeg2k mysql \
+netcdf odbc png ogdi perl postgres python ruby sqlite threads"
+
+RDEPEND=">=sys-libs/zlib-1.1.4
+ >=media-libs/tiff-3.7.0
+ sci-libs/libgeotiff
+ dev-libs/expat
+ curl? ( net-misc/curl )
+ jpeg? ( media-libs/jpeg )
+ gif? ( media-libs/giflib )
+ png? ( media-libs/libpng )
+ perl? ( dev-lang/perl )
+ python? ( virtual/python
+ dev-python/numpy )
+ ruby? ( >=dev-lang/ruby-1.8.4.20060226 )
+ fits? ( sci-libs/cfitsio )
+ ogdi? ( sci-libs/ogdi )
+ gml? ( =dev-libs/xerces-c-2.8* )
+ hdf5? ( >=sci-libs/hdf5-1.6.4 )
+ postgres? ( virtual/postgresql-server )
+ || (
+ netcdf? ( sci-libs/netcdf )
+ hdf? ( sci-libs/hdf )
+ )
+ || (
+ jpeg2k? ( media-libs/jasper )
+ ecwj2k? ( !media-libs/lcms
+ sci-libs/libecwj2 )
+ )
+ mysql? ( virtual/mysql )
+ odbc? ( dev-db/unixODBC )
+ geos? ( >=sci-libs/geos-2.2.1 )
+ sqlite? ( >=dev-db/sqlite-3 )"
+
+DEPEND="${RDEPEND}
+ ruby? ( >=dev-lang/swig-1.3.28 )
+ doc? ( app-doc/doxygen )"
+
+AT_M4DIR="${S}/m4"
+
+pkg_setup() {
+ if [ -n "${GDAL_CONFIGURE_OPTS}" ]; then
+ elog "User-specified configure options are ${GDAL_CONFIGURE_OPTS}."
+ else
+ elog "User-specified configure options are not set."
+ elog "If needed, set GDAL_CONFIGURE_OPTS to enable grass support."
+ fi
+}
+
+src_unpack() {
+ unpack ${A}
+ cd "${S}"
+
+ eaclocal
+ eautoconf
+
+ epatch "${FILESDIR}"/${PN}-1.4.2-datadir.patch \
+ "${FILESDIR}"/${PN}-1.5.0-soname.patch \
+ "${FILESDIR}"/${PN}-1.5.0-makefile.patch \
+ "${FILESDIR}"/${PN}-1.5.1-python-install.patch
+
+ if useq netcdf && useq hdf; then
+ einfo "Checking if HDF4 is compiled with szip..."
+ if built_with_use sci-libs/hdf szip ; then
+ einfo "Found HDF4 compiled with szip. Nice."
+ else
+ ewarn "HDF4 (sci-libs/hdf) must be compiled with the szip USE flag!"
+ einfo "Please emerge hdf with szip USE flag and then emerge GDAL."
+ die "HDF4 not merged with szip use flag"
+ fi
+ fi
+}
+
+src_compile() {
+
+ distutils_python_version
+
+ local pkg_conf="${GDAL_CONFIGURE_OPTS}"
+ local use_conf=""
+
+ pkg_conf="${pkg_conf} --enable-shared=yes --with-pic \
+ --with-libgrass=no --without-libtool"
+
+ use_conf="$(use_with jpeg) $(use_with png) $(use_with mysql) \
+ $(use_with postgres pg) $(use_with python) $(use_with ruby) \
+ $(use_with threads) $(use_with fits cfitsio) $(use_with perl) \
+ $(use_with netcdf) $(use_with hdf hdf4) $(use_with geos) \
+ $(use_with sqlite sqlite3) $(use_with jpeg2k jasper) $(use_with odbc) \
+ $(use_with gml xerces) $(use_with hdf5) $(use_with curl) \
+ $(use_enable debug)"
+
+ # It can't find this
+ if useq ogdi ; then
+ use_conf="--with-ogdi=/usr/$(get_libdir) ${use_conf}"
+ fi
+
+ if useq mysql ; then
+ use_conf="--with-mysql=/usr/bin/mysql_config ${use_conf}"
+ fi
+
+ if useq gif ; then
+ use_conf="--with-gif=internal ${use_conf}"
+ else
+ use_conf="--with-gif=no ${use_conf}"
+ fi
+
+ if useq python ; then
+ use_conf="--with-pymoddir=/usr/$(get_libdir)/python${PYVER}/site-packages \
+ ${use_conf}"
+ fi
+
+ # Fix doc path just in case
+ sed -i -e "s:@exec_prefix@/doc:/usr/share/doc/${PF}/html:g" \
+ GDALmake.opt.in || die "sed gdalmake.opt failed"
+
+ econf ${pkg_conf} ${use_conf} || die "econf failed"
+
+ # parallel makes fail on the ogr stuff (C++, what can I say?)
+ # also failing with gcc4 in libcsf
+ emake -j1 || die "emake failed"
+
+ if useq python; then
+ sed -i -e "s#library_dirs = #library_dirs = /usr/$(get_libdir):#g" \
+ swig/python/setup.cfg || die "sed python setup.cfg failed"
+ sed -i -e "s:\$(DESTDIR)\$(prefix):\$(DESTDIR)\$(INST_PREFIX):g" \
+ swig/python/GNUmakefile || die "sed python makefile failed"
+ fi
+
+ if useq perl ; then
+ cd "${S}"/swig/perl
+ perl-module_src_prep
+ perl-module_src_compile
+ cd "${S}"
+ fi
+
+ if useq doc ; then
+ make docs || die "make docs failed"
+ fi
+}
+
+src_install() {
+
+ if useq perl ; then
+ cd "${S}"/swig/perl
+ perl-module_src_install
+ sed -i -e "s:BINDINGS = python ruby perl:BINDINGS = python ruby:g" \
+ GDALmake.opt
+ cd "${S}"
+ fi
+
+ # einstall causes sandbox violations on /usr/lib/libgdal.so
+ make DESTDIR="${D}" install \
+ || die "make install failed"
+
+ dodoc Doxyfile HOWTO-RELEASE NEWS
+
+ if useq doc ; then
+ dohtml html/* || die "install html failed"
+ docinto ogr
+ dohtml ogr/html/* || die "install ogr html failed"
+ fi
+
+ if useq python; then
+ newdoc swig/python/README.txt README-python.txt
+ dodir /usr/share/${PN}/samples
+ insinto /usr/share/${PN}/samples
+ doins swig/python/samples/*
+ fi
+
+ use perl && fixlocalpod
+}
+
+pkg_postinst() {
+ elog
+ elog "If you need libgrass support, then you must rebuild gdal, after"
+ elog "installing the latest Grass, and set the following option:"
+ elog
+ elog "GDAL_CONFIGURE_OPTS=--with-grass=${GRASS_HOME} emerge gdal"
+ elog
+ elog "GDAL is most useful with full graphics support enabled via various"
+ elog "USE flags: png, jpeg, gif, jpeg2k, etc. Also python, fits, ogdi,"
+ elog "geos, and support for either netcdf or HDF4 is available, as well as"
+ elog "grass, and mysql, sqlite, or postgres (grass support requires grass 6"
+ elog "and rebuilding gdal). HDF5 support is now included."
+ elog
+ elog "Note: tiff and geotiff are now hard depends, so no USE flags."
+ elog "Also, this package will check for netcdf before hdf, so if you"
+ elog "prefer hdf, please emerge hdf with USE=szip prior to emerging"
+ elog "gdal. Detailed API docs require doxygen (man pages are free)."
+ elog
+ elog "Check available image and data formats after building with"
+ elog "gdalinfo and ogrinfo (using the --formats switch)."
+ elog
+}
diff --git a/sci-libs/gdal/metadata.xml b/sci-libs/gdal/metadata.xml
index e75f43633c64..fc4675c70207 100644
--- a/sci-libs/gdal/metadata.xml
+++ b/sci-libs/gdal/metadata.xml
@@ -12,9 +12,11 @@
<use>
<flag name='fits'>Enable support for NASA's <pkg>sci-libs/cfitsio</pkg>
library</flag>
+ <flag name='ecwj2k'>Enable support for alternate jpeg2k library
+ <pkg>sci-libs/libecwj2</pkg></flag>
<flag name='geos'>Add support for geometry engine (<pkg>sci-libs/geos</pkg>
</flag>
- <flag name='gml'>Enable support for <pkg>dev-libs/xerces-c</pkg> API</flag>
+ <flag name='gml'>Enable support for <pkg>dev-libs/xerces-c</pkg> C++ API</flag>
<flag name='hdf'>Add support for the Hierarchical Data Format
(<pkg>sci-libs/hdf</pkg>)</flag>
<flag name='ogdi'>Enable support for the open geographic datastore interface