1 files changed, 42 insertions, 0 deletions
diff --git a/sci-libs/geos/geos-3.1.0.ebuild b/sci-libs/geos/geos-3.1.0.ebuild
new file mode 100644
index 000000000000..254934a40b31
--- /dev/null
+++ b/sci-libs/geos/geos-3.1.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/geos/geos-3.1.0.ebuild,v 1.1 2009/03/27 12:30:19 bicatali Exp $
+
+EAPI=2
+
+DESCRIPTION="Geometry engine library for Geographic Information Systems"
+HOMEPAGE="http://geos.refractions.net"
+SRC_URI="http://download.osgeo.org/geos/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc python ruby"
+
+RDEPEND="ruby? ( virtual/ruby )
+	python? ( virtual/python )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	ruby?  ( dev-lang/swig )
+	python? ( dev-lang/swig )"
+
+src_configure() {
+	econf $(use_enable python) $(use_enable ruby)
+}
+
+src_compile() {
+	emake || die "emake failed"
+	if use doc; then
+		cd "${S}/doc"
+		emake doxygen-html || die "doc generation failed"
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS NEWS README TODO
+	if use doc; then
+		cd "${S}/doc"
+		dohtml -r doxygen_docs/html/* || die
+	fi
+}