1 files changed, 61 insertions, 0 deletions
diff --git a/sci-biology/samtools/samtools-0.1.19-r2.ebuild b/sci-biology/samtools/samtools-0.1.19-r2.ebuild
new file mode 100644
index 000000000000..a105de74248f
--- /dev/null
+++ b/sci-biology/samtools/samtools-0.1.19-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/samtools/samtools-0.1.19-r2.ebuild,v 1.1 2014/03/23 15:29:13 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit eutils multilib python-r1 toolchain-funcs
+
+DESCRIPTION="Utilities for SAM (Sequence Alignment/Map), a format for large nucleotide sequence alignments"
+HOMEPAGE="http://samtools.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="examples"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+CDEPEND="sys-libs/ncurses"
+RDEPEND="${CDEPEND}
+	dev-lang/lua
+	dev-lang/perl"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-buildsystem.patch
+
+	sed -i 's~/software/bin/python~/usr/bin/env python~' "${S}"/misc/varfilter.py || die
+
+	tc-export CC AR
+}
+
+src_compile() {
+	local _ncurses="$(pkg-config --libs ncurses)"
+	emake dylib LIBCURSES="${_ncurses}"
+	emake LIBCURSES="${_ncurses}"
+}
+
+src_install() {
+	dobin samtools $(find bcftools misc -type f -executable)
+
+	python_replicate_script "${ED}"/usr/bin/varfilter.py
+
+	dolib.so libbam$(get_libname 1)
+	dosym libbam$(get_libname 1) /usr/$(get_libdir)/libbam$(get_libname)
+
+	insinto /usr/include/bam
+	doins *.h
+
+	doman ${PN}.1
+	dodoc AUTHORS NEWS
+
+	if use examples; then
+		insinto /usr/share/${PN}
+		doins -r examples
+	fi
+}