1 files changed, 50 insertions, 0 deletions
diff --git a/net-libs/zeromq/zeromq-4.0.4-r1.ebuild b/net-libs/zeromq/zeromq-4.0.4-r1.ebuild
new file mode 100644
index 000000000000..6c6004787884
--- /dev/null
+++ b/net-libs/zeromq/zeromq-4.0.4-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/zeromq/zeromq-4.0.4-r1.ebuild,v 1.1 2014/06/18 08:21:16 qnikst Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils
+
+DESCRIPTION="A brokerless kernel"
+HOMEPAGE="http://www.zeromq.org/"
+SRC_URI="http://download.zeromq.org/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="pgm static-libs test"
+
+RDEPEND="
+	dev-libs/libsodium
+	pgm? ( =net-libs/openpgm-5.2.122 )"
+DEPEND="${RDEPEND}
+	sys-apps/util-linux
+	pgm? ( virtual/pkgconfig )"
+
+src_prepare() {
+	einfo "Removing bundled OpenPGM library"
+	rm -fr "${S}"/foreign/openpgm/libpgm* || die
+	sed \
+		-e '/libzmq_werror=/s:yes:no:g' \
+		-i configure.ac || die
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=()
+	use pgm && myeconfargs+=( --with-system-pgm ) || myeconfargs+=( --without-pgm )
+	autotools-utils_src_configure
+}
+
+src_test() {
+	autotools-utils_src_test -j1
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	doman doc/*.[1-9]
+}