1 files changed, 42 insertions, 0 deletions
diff --git a/kde-base/kimono/kimono-4.8.0.ebuild b/kde-base/kimono/kimono-4.8.0.ebuild
new file mode 100644
index 000000000000..1a4d8e9b9fc1
--- /dev/null
+++ b/kde-base/kimono/kimono-4.8.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kimono/kimono-4.8.0.ebuild,v 1.1 2012/01/25 18:16:51 johu Exp $
+
+EAPI=4
+
+KDE_SCM="git"
+inherit kde4-base mono
+
+DESCRIPTION="C# bindings for KDE"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="akonadi debug plasma semantic-desktop"
+
+DEPEND="
+	dev-lang/mono
+	$(add_kdebase_dep qyoto 'webkit')
+	$(add_kdebase_dep smokeqt)
+	$(add_kdebase_dep smokekde 'akonadi?,semantic-desktop=')
+	plasma? ( $(add_kdebase_dep smokeqt 'webkit') )
+	semantic-desktop? ( >=dev-libs/soprano-2.6.51[clucene] )
+"
+RDEPEND="${DEPEND}"
+
+# Split from kdebindings-csharp in 4.7
+add_blocker kdebindings-csharp
+
+src_prepare() {
+	kde4-base_src_prepare
+
+	sed -i "/add_subdirectory( examples )/ s:^:#:" plasma/CMakeLists.txt
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with akonadi)
+		$(cmake-utils_use_with akonadi KdepimLibs)
+		$(cmake-utils_use_disable plasma)
+		$(cmake-utils_use_with semantic-desktop Nepomuk)
+		$(cmake-utils_use_with semantic-desktop Soprano)
+	)
+	kde4-base_src_configure
+}