1 files changed, 62 insertions, 0 deletions
diff --git a/kde-base/gwenview/gwenview-4.10.5-r1.ebuild b/kde-base/gwenview/gwenview-4.10.5-r1.ebuild
new file mode 100644
index 000000000000..29248d249193
--- /dev/null
+++ b/kde-base/gwenview/gwenview-4.10.5-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/gwenview/gwenview-4.10.5-r1.ebuild,v 1.1 2013/08/03 01:25:21 jcallen Exp $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+inherit kde4-base
+
+DESCRIPTION="KDE image viewer"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug kipi semantic-desktop"
+
+# tests hang, last checked for 4.2.96
+RESTRICT="test"
+
+DEPEND="
+	$(add_kdebase_dep kdelibs 'semantic-desktop(+)?')
+	$(add_kdebase_dep libkonq)
+	$(add_kdebase_dep kactivities)
+	>=media-gfx/exiv2-0.19
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	virtual/jpeg
+	x11-libs/libX11
+	kipi? ( $(add_kdebase_dep libkipi) )
+"
+RDEPEND="${DEPEND}"
+
+KMLOADLIBS="libkonq"
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_with semantic-desktop Soprano)
+		$(cmake-utils_use_with kipi)
+	)
+
+	if use semantic-desktop; then
+		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=Nepomuk)
+	else
+		mycmakeargs+=(-DGWENVIEW_SEMANTICINFO_BACKEND=None)
+	fi
+
+	# Workaround for bug #479510
+	if [[ -e ${EPREFIX}/usr/include/${CHOST}/jconfig.h ]]; then
+		mycmakeargs+=( -DJCONFIG_H="${EPREFIX}/usr/include/${CHOST}/jconfig.h" )
+	fi
+
+	kde4-base_src_configure
+}
+
+pkg_postinst() {
+	kde4-base_pkg_postinst
+
+	if ! has_version kde-base/svgpart:${SLOT} ; then
+		elog "For SVG support, install kde-base/svgpart:${SLOT}"
+	fi
+
+	if use kipi && ! has_version media-plugins/kipi-plugins ; then
+		elog "The plugins for the KIPI inteface can be found in media-plugins/kipi-plugins"
+	fi
+}