1 files changed, 48 insertions, 0 deletions
diff --git a/games-emulation/stella/stella-2.4.ebuild b/games-emulation/stella/stella-2.4.ebuild
new file mode 100644
index 000000000000..c4f03d5fd113
--- /dev/null
+++ b/games-emulation/stella/stella-2.4.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/stella/stella-2.4.ebuild,v 1.1 2007/08/21 03:20:52 mr_bones_ Exp $
+
+inherit eutils games
+
+DESCRIPTION="Stella Atari 2600 VCS Emulator"
+HOMEPAGE="http://stella.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="opengl"
+
+DEPEND="media-libs/libsdl
+	media-libs/libpng
+	opengl? ( virtual/opengl )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i \
+		-e '/INSTALL/s/-s //' \
+		-e '/strip/d' \
+		-e "/icons/d" \
+		Makefile \
+		|| die "sed failed"
+}
+
+src_compile() {
+	# not an autoconf script
+	./configure \
+		--prefix="/usr" \
+		--bindir="${GAMES_BINDIR}" \
+		--docdir="/usr/share/doc/${PF}" \
+		--datadir="${GAMES_DATADIR}" \
+		$(use_enable opengl) \
+		|| die
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	doicon src/common/stella.xpm
+	make_desktop_entry stella Stella stella.xpm
+	prepgamesdirs
+}