1 files changed, 45 insertions, 0 deletions
diff --git a/dev-util/geany/geany-0.18.1.ebuild b/dev-util/geany/geany-0.18.1.ebuild
new file mode 100644
index 000000000000..9e1b10e41c37
--- /dev/null
+++ b/dev-util/geany/geany-0.18.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/geany/geany-0.18.1.ebuild,v 1.1 2010/02/14 18:56:12 ssuominen Exp $
+
+EAPI=2
+inherit gnome2-utils
+
+DESCRIPTION="GTK+ based fast and lightweight IDE"
+HOMEPAGE="http://geany.uvena.de"
+SRC_URI="http://files.uvena.de/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2 Scintilla"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE="+vte"
+
+RDEPEND=">=x11-libs/gtk+-2.12:2
+	>=dev-libs/glib-2.16:2
+	vte? ( x11-libs/vte )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	dev-util/intltool
+	sys-devel/gettext"
+
+src_prepare() {
+	# Syntax highlighting for Portage
+	sed -i -e "s:*.sh;:*.sh;*.ebuild;*.eclass;:" \
+		data/filetype_extensions.conf || die
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable vte)
+}
+
+src_install() {
+	emake DESTDIR="${D}" DOCDIR="${D}/usr/share/doc/${PF}" install || die
+	rm -f "${D}"/usr/share/doc/${PF}/{COPYING,GPL-2,ScintillaLicense.txt}
+	prepalldocs
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }