1 files changed, 57 insertions, 0 deletions
diff --git a/dev-scheme/gauche/gauche-0.8.11.ebuild b/dev-scheme/gauche/gauche-0.8.11.ebuild
new file mode 100644
index 000000000000..484dba214abd
--- /dev/null
+++ b/dev-scheme/gauche/gauche-0.8.11.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-scheme/gauche/gauche-0.8.11.ebuild,v 1.1 2007/08/25 14:51:43 hattya Exp $
+
+inherit autotools eutils flag-o-matic
+
+IUSE="ipv6"
+
+MY_P="${P/g/G}"
+
+DESCRIPTION="A Unix system friendly Scheme Interpreter"
+HOMEPAGE="http://gauche.sf.net/"
+SRC_URI="mirror://sourceforge/gauche/${MY_P}.tgz"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86"
+SLOT="0"
+S="${WORKDIR}/${MY_P}"
+
+DEPEND=">=sys-libs/gdbm-1.8.0"
+
+src_unpack() {
+
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PN}-gauche.m4.diff
+	epatch "${FILESDIR}"/${PN}-runpath.diff
+	eautoconf
+
+}
+
+src_compile() {
+
+	strip-flags
+
+	econf \
+		`use_enable ipv6` \
+		--enable-multibyte=utf8 \
+		--with-slib=/usr/share/slib \
+		|| die
+	emake -j1 || die
+
+}
+
+src_test() {
+
+	emake -j1 -s check || die
+
+}
+
+src_install() {
+
+	emake DESTDIR="${D}" install-pkg install-doc || die
+	dodoc AUTHORS ChangeLog HACKING README
+
+}